diff --git a/cmake/modules/InstallationHelper.cmake b/cmake/modules/InstallationHelper.cmake
index 3e4f7ea62..eb31c1cfd 100644
--- a/cmake/modules/InstallationHelper.cmake
+++ b/cmake/modules/InstallationHelper.cmake
@@ -1,221 +1,229 @@
 # This file contains facilities for installing the files.
 
 include(GNUInstallDirs)
 include(SanitizeHelper)
 
 function(_add_install_target COMPONENT)
 	cmake_parse_arguments(ARG
 		"EXCLUDE_FROM_ALL"
 		""
 		"DEPENDS"
 		${ARGN}
 	)
 
 	sanitize_target_name("install-" "${COMPONENT}" INSTALL_TARGET)
 
 	if(NOT TARGET ${INSTALL_TARGET})
 		add_custom_target(${INSTALL_TARGET}
 			COMMENT "Installing component ${COMPONENT}"
 			COMMAND
 				"${CMAKE_COMMAND}"
 				-E env CMAKE_INSTALL_ALWAYS=ON
 				"${CMAKE_COMMAND}"
 				-DCOMPONENT="${COMPONENT}"
 				-DCMAKE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 				-P cmake_install.cmake
 			WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
 		)
 
 		if(TARGET install-all)
 			add_dependencies(install-all ${INSTALL_TARGET})
 		endif()
 	endif()
 
 	# Other arguments are additional dependencies
 	if(ARG_DEPENDS)
 		add_dependencies(${INSTALL_TARGET} ${ARG_DEPENDS})
 	endif()
 
 	if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 		if(NOT TARGET "install-${COMPONENT}-debug")
 			add_custom_target("install-${COMPONENT}-debug"
 				COMMENT "Splitting out the debug symbols for component ${COMPONENT}"
 				COMMAND
 					"${CMAKE_SOURCE_DIR}/cmake/utils/split-installed-component.sh"
 					"${CMAKE_BINARY_DIR}/contrib/devtools/split-debug.sh"
 					"${CMAKE_BINARY_DIR}/install_manifest_${COMPONENT}.txt"
 					"${CMAKE_INSTALL_BINDIR}"
 					"${CMAKE_INSTALL_LIBDIR}"
 				DEPENDS
 					"${INSTALL_TARGET}"
 					"${CMAKE_BINARY_DIR}/contrib/devtools/split-debug.sh"
 			)
 		endif()
 
 		if(NOT ARG_EXCLUDE_FROM_ALL AND TARGET install-debug)
 			add_dependencies(install-debug "install-${COMPONENT}-debug")
 		endif()
 
 		if(TARGET install-all-debug)
 			add_dependencies(install-all-debug "install-${COMPONENT}-debug")
 		endif()
 	endif()
 endfunction()
 
 function(install_target _target)
 	cmake_parse_arguments(ARG
 		"EXCLUDE_FROM_ALL"
 		"COMPONENT"
 		""
 		${ARGN}
 	)
 
 	if(NOT ARG_COMPONENT)
 		set(ARG_COMPONENT ${PROJECT_NAME})
 	endif()
 
 	if(ARG_EXCLUDE_FROM_ALL)
 		set(INSTALL_EXCLUDE_FROM_ALL EXCLUDE_FROM_ALL)
 	endif()
 
 	set(COMMON_INSTALL_ARGUMENTS
 		COMPONENT ${ARG_COMPONENT}
 		${INSTALL_EXCLUDE_FROM_ALL}
 		${ARG_UNPARSED_ARGUMENTS}
 	)
 
 	install(
 		TARGETS ${_target}
 		RUNTIME
 			DESTINATION "${CMAKE_INSTALL_BINDIR}"
 			${COMMON_INSTALL_ARGUMENTS}
 		ARCHIVE
 			DESTINATION "${CMAKE_INSTALL_LIBDIR}"
 			${COMMON_INSTALL_ARGUMENTS}
 		LIBRARY
 			DESTINATION "${CMAKE_INSTALL_LIBDIR}"
 			${COMMON_INSTALL_ARGUMENTS}
 		PUBLIC_HEADER
 			DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
 			${COMMON_INSTALL_ARGUMENTS}
 	)
 
 	_add_install_target("${ARG_COMPONENT}"
 		${INSTALL_EXCLUDE_FROM_ALL}
 		DEPENDS ${_target}
 	)
 endfunction()
 
 function(install_shared_library NAME)
 	cmake_parse_arguments(ARG
 		"EXCLUDE_FROM_ALL"
 		""
 		"PUBLIC_HEADER"
 		${ARGN}
 	)
 
 	set(_sources ${ARG_UNPARSED_ARGUMENTS})
 
 	get_target_property(_target_type ${NAME} TYPE)
 	if(_target_type STREQUAL "SHARED_LIBRARY")
 		set(_shared_name "${NAME}")
 		target_sources(${NAME} PRIVATE ${_sources})
 	else()
 		set(_shared_name "${NAME}-shared")
 		add_library(${_shared_name} SHARED ${_sources})
 		target_link_libraries(${_shared_name} ${NAME})
 	endif()
 
 	if(ARG_PUBLIC_HEADER)
 		set_property(TARGET ${_shared_name} PROPERTY PUBLIC_HEADER ${ARG_PUBLIC_HEADER})
 	endif()
 
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 		# FIXME For compatibility reason with autotools, the version is set
 		# to 0.0.0 (major being actually 0). This is obviously wrong and the
 		# version of the library should reflect the version of the release.
 		# On platforms other than linux, only the major version (0) is used.
 		# Replace the VERSION line with the statement below to set the
 		# correct version:
 		# set(_properties VERSION "${CMAKE_PROJECT_VERSION}")
 		list(APPEND _properties VERSION "${CMAKE_PROJECT_VERSION_MAJOR}.0.0")
 	else()
 		list(APPEND _properties VERSION "${CMAKE_PROJECT_VERSION_MAJOR}")
 	endif()
 
 	# For autotools compatibility, rename the library to ${OUTPUT_NAME}-0.dll
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		list(APPEND _properties OUTPUT_NAME "${NAME}-${CMAKE_PROJECT_VERSION_MAJOR}")
 		# DLL_EXPORT is defined by libtool, and is expected by some sources.
 		target_compile_definitions(${_shared_name} PRIVATE DLL_EXPORT)
 	else()
 		list(APPEND _properties OUTPUT_NAME "${NAME}")
 	endif()
 
 	list(APPEND _properties SOVERSION "${CMAKE_PROJECT_VERSION_MAJOR}")
 
 	set_target_properties(${_shared_name} PROPERTIES ${_properties})
 
 	# Forward EXCLUDE_FROM_ALL if set
 	if(ARG_EXCLUDE_FROM_ALL)
 		set(FORWARD_EXCLUDE_FROM_ALL EXCLUDE_FROM_ALL)
 	endif()
 
 	install_target(${_shared_name} ${FORWARD_EXCLUDE_FROM_ALL})
 endfunction()
 
-function(install_manpage TARGET)
-	set(MAN_DESTINATION "${CMAKE_INSTALL_MANDIR}/man1")
+function(install_manpages TARGET)
 
-	set(MAN_PAGE "${CMAKE_BINARY_DIR}/doc/man/${TARGET}.1")
-	add_custom_command(
-		OUTPUT "${MAN_PAGE}"
-		COMMENT "Generating man page for ${TARGET}"
-		COMMAND
-			"${CMAKE_SOURCE_DIR}/doc/man/gen-manpages.sh"
-			"$<TARGET_FILE:bitcoind>"
-			"$<TARGET_FILE:${TARGET}>"
-			"${MAN_PAGE}"
-		DEPENDS
-			bitcoind
-			"${TARGET}"
+	define_property(TARGET
+		PROPERTY MAN_PAGES
+		BRIEF_DOCS "The man pages associated with the target"
+		FULL_DOCS "A list of the man pages associated with a target"
 	)
-	add_custom_target(gen-manpage-${TARGET}
-		DEPENDS "${MAN_PAGE}"
+
+	set_property(
+		TARGET ${TARGET}
+		APPEND PROPERTY MAN_PAGES ${ARGN}
 	)
 
+	define_property(GLOBAL
+		PROPERTY TARGETS_TO_GENERATE_MAN_PAGES
+		BRIEF_DOCS "Targets with generated man pages"
+		FULL_DOCS "A list of the targets that require their man pages to be generated"
+	)
+
+	# If no man page is given for this target, assume it should be generated
+	if(NOT ARGN)
+		set_property(
+			GLOBAL
+			APPEND PROPERTY TARGETS_TO_GENERATE_MAN_PAGES ${TARGET}
+		)
+	endif()
+
+	set(MAN_DESTINATION "${CMAKE_INSTALL_MANDIR}/man1")
+
 	install(
-		FILES "${MAN_PAGE}"
+		FILES "$<TARGET_PROPERTY:${TARGET},MAN_PAGES>"
 		DESTINATION "${MAN_DESTINATION}"
 		COMPONENT manpage-${TARGET}
 		EXCLUDE_FROM_ALL
 	)
 
 	_add_install_target(manpage-${TARGET}
-		DEPENDS gen-manpage-${TARGET}
 		EXCLUDE_FROM_ALL
 	)
 	_add_install_target(manpages
 		DEPENDS install-manpage-${TARGET}
 		EXCLUDE_FROM_ALL
 	)
 
 	if(NOT TARGET install-manpages-html)
 		set(INPUT_DIR "${CMAKE_INSTALL_PREFIX}/${MAN_DESTINATION}")
 		set(OUTPUT_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_MANDIR}/html")
 		configure_file(
 			"${CMAKE_SOURCE_DIR}/cmake/templates/man2html.sh.in"
 			"${CMAKE_BINARY_DIR}/config/man2html.sh"
 			@ONLY
 		)
 
 		add_custom_target(install-manpages-html
 			COMMENT "Generating man pages for web rendering"
 			COMMAND
 				"${CMAKE_BINARY_DIR}/config/man2html.sh"
 			DEPENDS
 				install-manpages
 				"${CMAKE_BINARY_DIR}/config/man2html.sh"
 		)
 	endif()
 endfunction()
diff --git a/doc/CMakeLists.txt b/doc/CMakeLists.txt
index 663d09197..8b7b5247f 100644
--- a/doc/CMakeLists.txt
+++ b/doc/CMakeLists.txt
@@ -1,5 +1,6 @@
 # Copyright (c) 2019 The Bitcoin developers
 
 configure_file(Doxyfile.cmake.in Doxyfile ESCAPE_QUOTES)
 
+add_subdirectory(man)
 add_subdirectory(rpc)
diff --git a/doc/man/CMakeLists.txt b/doc/man/CMakeLists.txt
new file mode 100644
index 000000000..523c45ea3
--- /dev/null
+++ b/doc/man/CMakeLists.txt
@@ -0,0 +1,52 @@
+function(generate_manpages)
+	get_property(TARGETS
+		GLOBAL
+		PROPERTY TARGETS_TO_GENERATE_MAN_PAGES
+	)
+
+	foreach(TARGET ${TARGETS})
+		if(NOT TARGET ${TARGET})
+			continue()
+		endif()
+
+		set(MAN_PAGE "${CMAKE_BINARY_DIR}/doc/man/${TARGET}.1")
+
+		add_custom_command(
+			OUTPUT "${MAN_PAGE}"
+			COMMENT "Generating man page for ${TARGET}"
+			COMMAND
+				"${CMAKE_SOURCE_DIR}/doc/man/gen-manpages.sh"
+				"$<TARGET_FILE:bitcoind>"
+				"$<TARGET_FILE:${TARGET}>"
+				"${MAN_PAGE}"
+			DEPENDS
+				bitcoind
+				"${TARGET}"
+		)
+		add_custom_target(gen-manpage-${TARGET}
+			DEPENDS "${MAN_PAGE}"
+		)
+
+		set_property(
+			TARGET ${TARGET}
+			APPEND PROPERTY MAN_PAGES "${MAN_PAGE}"
+		)
+
+		if(TARGET install-manpage-${TARGET})
+			add_dependencies(install-manpage-${TARGET} gen-manpage-${TARGET})
+		endif()
+	endforeach()
+endfunction()
+
+function(_generate_manpages_hook VAR ACCESS)
+	# When CMAKE_CURRENT_LIST_DIR is set to empty, we add the man pages
+	# generation targets. This ensures all targets are created when this
+	# function runs independently of the list files inclusion order.
+	if("${VAR}" STREQUAL "CMAKE_CURRENT_LIST_DIR" AND
+		"${CMAKE_CURRENT_LIST_DIR}" STREQUAL "" AND
+		"${ACCESS}" STREQUAL "MODIFIED_ACCESS")
+		generate_manpages()
+	endif()
+endfunction()
+
+variable_watch(CMAKE_CURRENT_LIST_DIR _generate_manpages_hook)
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
index e4454bf05..afcacd1d3 100644
--- a/src/CMakeLists.txt
+++ b/src/CMakeLists.txt
@@ -1,667 +1,667 @@
 # Copyright (c) 2017 The Bitcoin developers
 
 project(bitcoind)
 
 set(CMAKE_CXX_STANDARD 14)
 
 # Default visibility is hidden on all targets.
 set(CMAKE_C_VISIBILITY_PRESET hidden)
 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
 
 option(BUILD_BITCOIN_WALLET "Activate the wallet functionality" ON)
 option(BUILD_BITCOIN_ZMQ "Activate the ZeroMQ functionalities" ON)
 option(BUILD_BITCOIN_CLI "Build bitcoin-cli" ON)
 option(BUILD_BITCOIN_TX "Build bitcoin-tx" ON)
 option(BUILD_BITCOIN_QT "Build bitcoin-qt" ON)
 option(BUILD_BITCOIN_SEEDER "Build bitcoin-seeder" ON)
 option(BUILD_LIBBITCOINCONSENSUS "Build the bitcoinconsenus shared library" ON)
 option(ENABLE_BIP70 "Enable BIP70 (payment protocol) support in GUI" ON)
 option(ENABLE_HARDENING "Harden the executables" ON)
 option(ENABLE_REDUCE_EXPORTS "Reduce the amount of exported symbols" OFF)
 option(ENABLE_STATIC_LIBSTDCXX "Statically link libstdc++" OFF)
 option(ENABLE_GLIBC_BACK_COMPAT "Enable Glibc compatibility features" OFF)
 option(ENABLE_QRCODE "Enable QR code display" ON)
 option(ENABLE_UPNP "Enable UPnP support" ON)
 option(START_WITH_UPNP "Make UPnP the default to map ports" OFF)
 option(ENABLE_CLANG_TIDY "Enable clang-tidy checks for Bitcoin ABC" OFF)
 option(ENABLE_PROFILING "Select the profiling tool to use" OFF)
 option(USE_LD_GOLD "Try to use gold as a linker if available" ON)
 
 set(OS_WITH_JEMALLOC_AS_SYSTEM_DEFAULT
 	"Android"
 	"FreeBSD"
 	"NetBSD"
 )
 if(NOT CMAKE_SYSTEM_NAME IN_LIST OS_WITH_JEMALLOC_AS_SYSTEM_DEFAULT)
 	set(USE_JEMALLOC_DEFAULT ON)
 endif()
 option(USE_JEMALLOC "Use jemalloc as an allocation library" ${USE_JEMALLOC_DEFAULT})
 
 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 	set(DEFAULT_ENABLE_DBUS_NOTIFICATIONS ON)
 endif()
 option(ENABLE_DBUS_NOTIFICATIONS "Enable DBus desktop notifications. Linux only." ${DEFAULT_ENABLE_DBUS_NOTIFICATIONS})
 
 # If ccache is available, then use it.
 find_program(CCACHE ccache)
 if(CCACHE)
 	message(STATUS "Using ccache: ${CCACHE}")
 	set(CMAKE_C_COMPILER_LAUNCHER ${CCACHE})
 	set(CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE})
 endif(CCACHE)
 
 # Disable what we do not need for the native build.
 include(NativeExecutable)
 native_add_cmake_flags(
 	"-DBUILD_BITCOIN_WALLET=OFF"
 	"-DBUILD_BITCOIN_QT=OFF"
 	"-DBUILD_BITCOIN_ZMQ=OFF"
 	"-DENABLE_QRCODE=OFF"
 	"-DENABLE_UPNP=OFF"
 	"-DUSE_JEMALLOC=OFF"
 	# Forward the current setting for clang-tidy
 	"-DENABLE_CLANG_TIDY=${ENABLE_CLANG_TIDY}"
 )
 
 if(ENABLE_CLANG_TIDY)
 	include(ClangTidy)
 endif()
 
 if(ENABLE_SANITIZERS)
 	include(Sanitizers)
 	enable_sanitizers(${ENABLE_SANITIZERS})
 endif()
 
 include(AddCompilerFlags)
 
 if(USE_LD_GOLD)
 	add_linker_flags(-fuse-ld=gold)
 endif()
 
 # Prefer -g3, defaults to -g if unavailable
 foreach(LANGUAGE C CXX)
 	set(COMPILER_DEBUG_LEVEL -g)
 	check_compiler_flags(G3_IS_SUPPORTED ${LANGUAGE} -g3)
 	if(${G3_IS_SUPPORTED})
 		set(COMPILER_DEBUG_LEVEL -g3)
 	endif()
 	add_compile_options_to_configuration_for_language(Debug ${LANGUAGE} ${COMPILER_DEBUG_LEVEL})
 endforeach()
 
 # Define the debugging symbols DEBUG and DEBUG_LOCKORDER when the Debug build
 # type is selected.
 add_compile_definitions_to_configuration(Debug DEBUG DEBUG_LOCKORDER)
 
 # Add -ftrapv when building in Debug
 add_compile_options_to_configuration(Debug -ftrapv)
 
 # All versions of gcc that we commonly use for building are subject to bug
 # https://gcc.gnu.org/bugzilla/show_bug.cgi?id=90348. To work around that, set
 # -fstack-reuse=none for all gcc builds. (Only gcc understands this flag)
 if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
 	add_compiler_flags(-fstack-reuse=none)
 endif()
 
 # Ensure that WINDRES_PREPROC is enabled when using windres.
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	# Ensure that WINDRES_PREPROC is enabled when using windres.
 	list(APPEND CMAKE_RC_FLAGS "-DWINDRES_PREPROC")
 
 	# Build all static so there is no dll file to distribute.
 	add_linker_flags(-static)
 endif()
 
 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 	add_compile_definitions(MAC_OSX OBJC_OLD_DISPATCH_PROTOTYPES=0)
 	add_linker_flags(-Wl,-dead_strip_dylibs)
 endif()
 
 if(ENABLE_REDUCE_EXPORTS)
 	# Default visibility is set by CMAKE_<LANG>_VISIBILITY_PRESET, but this
 	# doesn't tell if the visibility set is effective.
 	# Check if the flag -fvisibility=hidden is supported, as using the hidden
 	# visibility is a requirement to reduce exports.
 	check_compiler_flags(HAS_CXX_FVISIBILITY CXX -fvisibility=hidden)
 	if(NOT HAS_CXX_FVISIBILITY)
 		message(FATAL_ERROR "Cannot set default symbol visibility. Use -DENABLE_REDUCE_EXPORTS=OFF.")
 	endif()
 
 	# Also hide symbols from static libraries
 	add_linker_flags(-Wl,--exclude-libs,libstdc++)
 endif()
 
 # Enable statically linking libstdc++
 if(ENABLE_STATIC_LIBSTDCXX)
 	add_linker_flags(-static-libstdc++)
 endif()
 
 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 
 if(ENABLE_HARDENING)
 	# Enable stack protection
 	add_cxx_compiler_flags(-fstack-protector-all -Wstack-protector)
 
 	# Enable some buffer overflow checking, except in -O0 builds which
 	# do not support them
 	add_compiler_flags(-U_FORTIFY_SOURCE)
 	add_compile_options($<$<NOT:$<CONFIG:Debug>>:-D_FORTIFY_SOURCE=2>)
 
 	# Enable ASLR (these flags are primarily targeting MinGw)
 	add_linker_flags(-Wl,--dynamicbase -Wl,--nxcompat -Wl,--high-entropy-va)
 
 	# Make the relocated sections read-only
 	add_linker_flags(-Wl,-z,relro -Wl,-z,now)
 
 	# CMake provides the POSITION_INDEPENDENT_CODE property to set PIC/PIE.
 	cmake_policy(SET CMP0083 NEW)
 	include(CheckPIESupported)
 	check_pie_supported()
 
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		# MinGw provides its own libssp for stack smashing protection
 		link_libraries(ssp)
 	endif()
 endif()
 
 if(ENABLE_PROFILING MATCHES "gprof")
 	message(STATUS "Enable profiling with gprof")
 
 	# -pg is incompatible with -pie. Since hardening and profiling together
 	# doesn't make sense, we simply make them mutually exclusive here.
 	# Additionally, hardened toolchains may force -pie by default, in which
 	# case it needs to be turned off with -no-pie.
 	if(ENABLE_HARDENING)
 		message(FATAL_ERROR "Profiling with gprof requires disabling hardening with -DENABLE_HARDENING=OFF.")
 	endif()
 	add_linker_flags(-no-pie)
 
 	add_compiler_flags(-pg)
 	add_linker_flags(-pg)
 endif()
 
 # Enable warning
 add_c_compiler_flags(-Wnested-externs -Wstrict-prototypes)
 add_compiler_flags(
 	-Wall
 	-Wextra
 	-Wformat
 	-Wvla
 	-Wcast-align
 	-Wunused-parameter
 	-Wmissing-braces
 	-Wthread-safety-analysis
 	-Wshadow
 	-Wshadow-field
 	-Wrange-loop-analysis
 	-Wredundant-decls
 )
 add_compiler_flag_group(-Wformat -Wformat-security)
 add_cxx_compiler_flags(
 	-Wredundant-move
 )
 
 option(EXTRA_WARNINGS "Enable extra warnings" OFF)
 if(EXTRA_WARNINGS)
 	add_cxx_compiler_flags(-Wsuggest-override)
 else()
 	add_compiler_flags(-Wno-unused-parameter)
 	add_compiler_flags(-Wno-implicit-fallthrough)
 endif()
 
 # libtool style configure
 add_subdirectory(config)
 
 # Enable LFS (Large File Support) on targets that don't have it natively.
 # This should be defined before the libraries are included as leveldb need the
 # definition to be set.
 if(NOT HAVE_LARGE_FILE_SUPPORT)
 	add_compile_definitions(_FILE_OFFSET_BITS=64)
 	add_linker_flags(-Wl,--large-address-aware)
 endif()
 
 if(ENABLE_GLIBC_BACK_COMPAT)
 	# Wrap some glibc functions with ours
 	add_linker_flags(-Wl,--wrap=__divmoddi4)
 	add_linker_flags(-Wl,--wrap=log2f)
 
 	if(NOT HAVE_LARGE_FILE_SUPPORT)
 		add_linker_flags(-Wl,--wrap=fcntl -Wl,--wrap=fcntl64)
 	endif()
 endif()
 
 if(USE_JEMALLOC)
 	# Most of the sanitizers require their instrumented allocation functions to
 	# be fully functional. This is obviously the case for all the memory related
 	# sanitizers (asan, lsan, msan) but not only.
 	if(ENABLE_SANITIZERS)
 		message(WARNING "Jemalloc is incompatible with the sanitizers and has been disabled.")
 	else()
 		find_package(Jemalloc 3.6.0 REQUIRED)
 		link_libraries(Jemalloc::jemalloc)
 	endif()
 endif()
 
 
 # Make sure that all the global compiler and linker flags are set BEFORE
 # including the libraries so they apply as needed.
 
 
 # libraries
 add_subdirectory(crypto)
 add_subdirectory(leveldb)
 add_subdirectory(secp256k1)
 add_subdirectory(univalue)
 
 # Find the git root, and returns the full path to the .git/logs/HEAD file if
 # it exists.
 function(find_git_head_logs_file RESULT)
 	find_package(Git)
 	if(GIT_FOUND)
 		execute_process(
 			COMMAND "${GIT_EXECUTABLE}" "rev-parse" "--show-toplevel"
 			WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
 			OUTPUT_VARIABLE GIT_ROOT
 			RESULT_VARIABLE GIT_RESULT
 			OUTPUT_STRIP_TRAILING_WHITESPACE
 			ERROR_QUIET
 		)
 
 		if(GIT_RESULT EQUAL 0)
 			set(GIT_LOGS_DIR "${GIT_ROOT}/.git/logs")
 			set(GIT_HEAD_LOGS_FILE "${GIT_LOGS_DIR}/HEAD")
 			# If the .git/logs/HEAD does not exist, create it
 			if(NOT EXISTS "${GIT_HEAD_LOGS_FILE}")
 				file(MAKE_DIRECTORY "${GIT_LOGS_DIR}")
 				file(TOUCH "${GIT_HEAD_LOGS_FILE}")
 			endif()
 			set(${RESULT} "${GIT_HEAD_LOGS_FILE}" PARENT_SCOPE)
 		endif()
 	endif()
 endfunction()
 
 find_git_head_logs_file(GIT_HEAD_LOGS_FILE)
 
 set(OBJ_DIR "${CMAKE_CURRENT_BINARY_DIR}/obj")
 file(MAKE_DIRECTORY "${OBJ_DIR}")
 set(BUILD_HEADER "${OBJ_DIR}/build.h")
 set(BUILD_HEADER_TMP "${BUILD_HEADER}.tmp")
 
 add_custom_command(
 	DEPENDS
 		"${GIT_HEAD_LOGS_FILE}"
 		"${CMAKE_SOURCE_DIR}/share/genbuild.sh"
 	OUTPUT
 		"${BUILD_HEADER}"
 	COMMAND
 		"${CMAKE_SOURCE_DIR}/share/genbuild.sh"
 		"${BUILD_HEADER_TMP}"
 		"${CMAKE_SOURCE_DIR}"
 	COMMAND
 		${CMAKE_COMMAND} -E copy_if_different "${BUILD_HEADER_TMP}" "${BUILD_HEADER}"
 	COMMAND
 		${CMAKE_COMMAND} -E remove "${BUILD_HEADER_TMP}"
 )
 
 # Because the Bitcoin ABc source code is disorganised, we
 # end up with a bunch of libraries without any apparent
 # cohesive structure. This is inherited from Bitcoin Core
 # and reflecting this.
 # TODO: Improve the structure once cmake is rocking.
 
 # Various completely unrelated features shared by all executables.
 add_library(util
 	chainparamsbase.cpp
 	clientversion.cpp
 	compat/glibcxx_sanity.cpp
 	compat/strnlen.cpp
 	fs.cpp
 	interfaces/handler.cpp
 	logging.cpp
 	random.cpp
 	randomenv.cpp
 	rcu.cpp
 	rpc/request.cpp
 	support/cleanse.cpp
 	support/lockedpool.cpp
 	sync.cpp
 	threadinterrupt.cpp
 	uint256.cpp
 	util/bip32.cpp
 	util/bytevectorhash.cpp
 	util/error.cpp
 	util/moneystr.cpp
 	util/settings.cpp
 	util/spanparsing.cpp
 	util/strencodings.cpp
 	util/string.cpp
 	util/system.cpp
 	util/threadnames.cpp
 	util/time.cpp
 	util/url.cpp
 	util/validation.cpp
 
 	# obj/build.h
 	"${BUILD_HEADER}"
 )
 
 target_compile_definitions(util PUBLIC HAVE_CONFIG_H HAVE_BUILD_INFO)
 target_include_directories(util
 	PUBLIC
 		.
 		# To access the config/ and obj/ directories
 		${CMAKE_CURRENT_BINARY_DIR}
 )
 
 if(ENABLE_GLIBC_BACK_COMPAT)
 	target_sources(util PRIVATE compat/glibc_compat.cpp)
 endif()
 
 # Target specific configs
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	set(Boost_USE_STATIC_LIBS ON)
 	set(Boost_USE_STATIC_RUNTIME ON)
 	set(Boost_THREADAPI win32)
 
 	find_package(SHLWAPI REQUIRED)
 	target_link_libraries(util SHLWAPI::shlwapi)
 
 	find_library(WS2_32_LIBRARY NAMES ws2_32)
 	target_link_libraries(util ${WS2_32_LIBRARY})
 
 	target_compile_definitions(util PUBLIC BOOST_THREAD_USE_LIB)
 endif()
 
 # Boost packages
 set(BOOST_PACKAGES_REQUIRED chrono filesystem thread)
 
 function(prepend var prefix)
 	set(listVar "")
 	foreach(f ${ARGN})
 		list(APPEND listVar "${prefix}${f}")
 	endforeach(f)
 	set(${var} "${listVar}" PARENT_SCOPE)
 endfunction(prepend)
 
 prepend(BOOST_LIBRARIES "Boost::" ${BOOST_PACKAGES_REQUIRED})
 
 find_package(Boost 1.59 REQUIRED ${BOOST_PACKAGES_REQUIRED})
 
 # This require libevent
 set(EVENT_MIN_VERSION 2.0.22)
 find_package(Event ${EVENT_MIN_VERSION} REQUIRED COMPONENTS event)
 
 target_link_libraries(util univalue crypto Event::event ${BOOST_LIBRARIES})
 
 # Make sure boost uses std::atomic (it doesn't before 1.63)
 target_compile_definitions(util PUBLIC BOOST_SP_USE_STD_ATOMIC BOOST_AC_USE_STD_ATOMIC)
 
 # More completely unrelated features shared by all executables.
 # Because nothing says this is different from util than "common"
 add_library(common
 	amount.cpp
 	base58.cpp
 	bloom.cpp
 	cashaddr.cpp
 	cashaddrenc.cpp
 	chainparams.cpp
 	config.cpp
 	consensus/merkle.cpp
 	coins.cpp
 	compressor.cpp
 	eventloop.cpp
 	feerate.cpp
 	core_read.cpp
 	core_write.cpp
 	key.cpp
 	key_io.cpp
 	merkleblock.cpp
 	net_permissions.cpp
 	netaddress.cpp
 	netbase.cpp
 	outputtype.cpp
 	policy/policy.cpp
 	primitives/block.cpp
 	protocol.cpp
 	psbt.cpp
 	rpc/rawtransaction_util.cpp
 	rpc/util.cpp
 	scheduler.cpp
 	salteduint256hasher.cpp
 	versionbitsinfo.cpp
 	warnings.cpp
 )
 
 target_link_libraries(common util secp256k1 script)
 
 # script library
 add_library(script
 	script/bitfield.cpp
 	script/descriptor.cpp
 	script/interpreter.cpp
 	script/script.cpp
 	script/script_error.cpp
 	script/sigencoding.cpp
 	script/sign.cpp
 	script/signingprovider.cpp
 	script/standard.cpp
 )
 
 target_link_libraries(script common)
 
 # libbitcoinconsensus
 add_library(bitcoinconsensus
 	arith_uint256.cpp
 	hash.cpp
 	primitives/transaction.cpp
 	pubkey.cpp
 	uint256.cpp
 	util/strencodings.cpp
 	consensus/tx_check.cpp
 )
 
 target_link_libraries(bitcoinconsensus script)
 
 include(InstallationHelper)
 if(BUILD_LIBBITCOINCONSENSUS)
 	target_compile_definitions(bitcoinconsensus
 		PUBLIC
 			BUILD_BITCOIN_INTERNAL
 			HAVE_CONSENSUS_LIB
 	)
 
 	install_shared_library(bitcoinconsensus
 		script/bitcoinconsensus.cpp
 		PUBLIC_HEADER script/bitcoinconsensus.h
 	)
 endif()
 
 # Bitcoin server facilities
 add_library(server
 	addrdb.cpp
 	addrman.cpp
 	avalanche/peermanager.cpp
 	avalanche/processor.cpp
 	avalanche/proof.cpp
 	avalanche/proofbuilder.cpp
 	banman.cpp
 	blockencodings.cpp
 	blockfilter.cpp
 	blockindex.cpp
 	chain.cpp
 	checkpoints.cpp
 	config.cpp
 	consensus/activation.cpp
 	consensus/tx_verify.cpp
 	dbwrapper.cpp
 	flatfile.cpp
 	httprpc.cpp
 	httpserver.cpp
 	index/base.cpp
 	index/blockfilterindex.cpp
 	index/txindex.cpp
 	init.cpp
 	interfaces/chain.cpp
 	interfaces/node.cpp
 	miner.cpp
 	minerfund.cpp
 	net.cpp
 	net_processing.cpp
 	node/coin.cpp
 	node/coinstats.cpp
 	node/context.cpp
 	node/psbt.cpp
 	node/transaction.cpp
 	noui.cpp
 	policy/fees.cpp
 	policy/settings.cpp
 	pow/aserti32d.cpp
 	pow/daa.cpp
 	pow/eda.cpp
 	pow/pow.cpp
 	rest.cpp
 	rpc/abc.cpp
 	rpc/avalanche.cpp
 	rpc/blockchain.cpp
 	rpc/command.cpp
 	rpc/mining.cpp
 	rpc/misc.cpp
 	rpc/net.cpp
 	rpc/rawtransaction.cpp
 	rpc/server.cpp
 	script/scriptcache.cpp
 	script/sigcache.cpp
 	shutdown.cpp
 	timedata.cpp
 	torcontrol.cpp
 	txdb.cpp
 	txmempool.cpp
 	ui_interface.cpp
 	validation.cpp
 	validationinterface.cpp
 	versionbits.cpp
 )
 
 target_include_directories(server PRIVATE leveldb/helpers/memenv)
 
 target_link_libraries(server
 	Event::event
 	bitcoinconsensus
 	leveldb
 	memenv
 )
 
 if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	find_package(Event ${EVENT_MIN_VERSION} REQUIRED COMPONENTS pthreads)
 	target_link_libraries(server Event::pthreads)
 endif()
 
 if(ENABLE_UPNP)
 	find_package(MiniUPnPc 1.5 REQUIRED)
 	target_link_libraries(server MiniUPnPc::miniupnpc)
 
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		# TODO: check if we are really using a static library. Assume this is
 		# the one from the depends for now since the native windows build is not
 		# supported.
 		target_compile_definitions(server
 			PUBLIC -DSTATICLIB
 			PUBLIC -DMINIUPNP_STATICLIB
 		)
 	endif()
 endif()
 
 # Test suites.
 add_subdirectory(test)
 add_subdirectory(avalanche/test)
 add_subdirectory(pow/test)
 
 # Benchmark suite.
 add_subdirectory(bench)
 
 include(BinaryTest)
 
 # Wallet
 if(BUILD_BITCOIN_WALLET)
 	add_subdirectory(wallet)
 	target_link_libraries(server wallet)
 
 	# bitcoin-wallet
 	add_executable(bitcoin-wallet bitcoin-wallet.cpp)
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		target_sources(bitcoin-wallet PRIVATE bitcoin-wallet-res.rc)
 	endif()
 
 	target_link_libraries(bitcoin-wallet wallet-tool common util)
 
 	add_to_symbols_check(bitcoin-wallet)
 	add_to_security_check(bitcoin-wallet)
 
 	install_target(bitcoin-wallet)
-	install_manpage(bitcoin-wallet)
+	install_manpages(bitcoin-wallet)
 else()
 	target_sources(server PRIVATE dummywallet.cpp)
 endif()
 
 # ZeroMQ
 if(BUILD_BITCOIN_ZMQ)
 	add_subdirectory(zmq)
 	target_link_libraries(server zmq)
 endif()
 
 # RPC client support
 add_library(rpcclient rpc/client.cpp)
 target_link_libraries(rpcclient univalue util)
 
 # bitcoin-seeder
 if(BUILD_BITCOIN_SEEDER)
 	add_subdirectory(seeder)
 endif()
 
 # bitcoin-cli
 if(BUILD_BITCOIN_CLI)
 	add_executable(bitcoin-cli bitcoin-cli.cpp)
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		target_sources(bitcoin-cli PRIVATE bitcoin-cli-res.rc)
 	endif()
 
 	target_link_libraries(bitcoin-cli common rpcclient Event::event)
 
 	add_to_symbols_check(bitcoin-cli)
 	add_to_security_check(bitcoin-cli)
 
 	install_target(bitcoin-cli)
-	install_manpage(bitcoin-cli)
+	install_manpages(bitcoin-cli)
 endif()
 
 # bitcoin-tx
 if(BUILD_BITCOIN_TX)
 	add_executable(bitcoin-tx bitcoin-tx.cpp)
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		target_sources(bitcoin-tx PRIVATE bitcoin-tx-res.rc)
 	endif()
 
 	target_link_libraries(bitcoin-tx bitcoinconsensus)
 
 	add_to_symbols_check(bitcoin-tx)
 	add_to_security_check(bitcoin-tx)
 
 	install_target(bitcoin-tx)
-	install_manpage(bitcoin-tx)
+	install_manpages(bitcoin-tx)
 endif()
 
 # bitcoind
 add_executable(bitcoind bitcoind.cpp)
 target_link_libraries(bitcoind server)
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	target_sources(bitcoind PRIVATE bitcoind-res.rc)
 endif()
 add_to_symbols_check(bitcoind)
 add_to_security_check(bitcoind)
 
 install_target(bitcoind)
-install_manpage(bitcoind)
+install_manpages(bitcoind)
 
 # Bitcoin-qt
 if(BUILD_BITCOIN_QT)
 	add_subdirectory(qt)
 endif()
diff --git a/src/qt/CMakeLists.txt b/src/qt/CMakeLists.txt
index 5bdaa7b24..74d01b936 100644
--- a/src/qt/CMakeLists.txt
+++ b/src/qt/CMakeLists.txt
@@ -1,626 +1,626 @@
 # Copyright (c) 2018 The Bitcoin developers
 
 project(bitcoin-qt)
 
 include(BrewHelper)
 find_brew_prefix(QT5_PREFIX qt5)
 
 set(QT_REQUIRED_COMPONENTS Core Widgets Network Test)
 if(ENABLE_DBUS_NOTIFICATIONS)
 	list(APPEND QT_REQUIRED_COMPONENTS DBus)
 endif()
 
 find_package(Qt5 5.5.1 COMPONENTS ${QT_REQUIRED_COMPONENTS} REQUIRED HINTS "${QT5_PREFIX}")
 
 # Localisation
 add_subdirectory(locale)
 
 add_custom_command(OUTPUT temp_bitcoin_locale.qrc
 	COMMAND cmake
 	ARGS
 		-E copy
 		"${CMAKE_CURRENT_SOURCE_DIR}/bitcoin_locale.qrc"
 		temp_bitcoin_locale.qrc
 	MAIN_DEPENDENCY bitcoin_locale.qrc
 	VERBATIM
 )
 
 add_custom_command(OUTPUT qrc_bitcoin_locale.cpp
 	COMMAND Qt5::rcc
 	ARGS
 		temp_bitcoin_locale.qrc
 		-name bitcoin_locale
 		-o qrc_bitcoin_locale.cpp
 	MAIN_DEPENDENCY temp_bitcoin_locale.qrc
 	DEPENDS locales
 	VERBATIM
 )
 
 # UI elements
 # qt5_wrap_ui() generates the files in the CMAKE_CURRENT_BINARY_DIR. As there
 # is no option to change the output directory, moving the files to the forms
 # subdirectory requires to override the variable. It is reset to its actual
 # value after the call so it does not impact the other sections of this
 # CMakeLists.txt file.
 set(SAVE_CMAKE_CURRENT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 set(CMAKE_CURRENT_BINARY_DIR "${CMAKE_CURRENT_BINARY_DIR}/forms")
 
 # It seems that some generators (at least the Unix Makefiles one) doesn't create
 # the build directory required  by a custom command, so do it manually.
 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 
 qt5_wrap_ui(UI_GENERATED_HEADERS
 	forms/addressbookpage.ui
 	forms/askpassphrasedialog.ui
 	forms/coincontroldialog.ui
 	forms/createwalletdialog.ui
 	forms/editaddressdialog.ui
 	forms/helpmessagedialog.ui
 	forms/intro.ui
 	forms/modaloverlay.ui
 	forms/openuridialog.ui
 	forms/optionsdialog.ui
 	forms/overviewpage.ui
 	forms/receivecoinsdialog.ui
 	forms/receiverequestdialog.ui
 	forms/debugwindow.ui
 	forms/sendcoinsdialog.ui
 	forms/sendcoinsentry.ui
 	forms/signverifymessagedialog.ui
 	forms/transactiondescdialog.ui
 )
 set(CMAKE_CURRENT_BINARY_DIR ${SAVE_CMAKE_CURRENT_BINARY_DIR})
 
 # Qt MOC
 set(CMAKE_AUTOMOC ON)
 
 # Handle qrc resources
 qt5_add_resources(QRC_BITCOIN_CPP bitcoin.qrc)
 
 add_library(bitcoin-qt-base
 	bantablemodel.cpp
 	bitcoin.cpp
 	bitcoinaddressvalidator.cpp
 	bitcoinamountfield.cpp
 	bitcoingui.cpp
 	bitcoinunits.cpp
 	clientmodel.cpp
 	csvmodelwriter.cpp
 	guiutil.cpp
 	intro.cpp
 	modaloverlay.cpp
 	networkstyle.cpp
 	notificator.cpp
 	optionsdialog.cpp
 	optionsmodel.cpp
 	peertablemodel.cpp
 	platformstyle.cpp
 	qvalidatedlineedit.cpp
 	qvaluecombobox.cpp
 	rpcconsole.cpp
 	splashscreen.cpp
 	trafficgraphwidget.cpp
 	utilitydialog.cpp
 
 	# Handle ui files
 	${UI_GENERATED_HEADERS}
 
 	# Translations
 	${BITCOIN_QM_FILES}
 
 	# Handle qrc files
 	${QRC_BITCOIN_CPP}
 	qrc_bitcoin_locale.cpp
 )
 
 # Add the minimal integration plugin, and other plugins according to the target
 # platform.
 set(QT_PLUGIN_COMPONENTS QMinimalIntegrationPlugin)
 set(QT_PLUGIN_PLATFORM_DEFINITIONS -DQT_QPA_PLATFORM_MINIMAL=1)
 
 # Linux support
 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 	list(APPEND QT_PLUGIN_COMPONENTS QXcbIntegrationPlugin)
 	list(APPEND QT_PLUGIN_PLATFORM_DEFINITIONS -DQT_QPA_PLATFORM_XCB=1)
 endif()
 
 # Windows support
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	list(APPEND QT_PLUGIN_COMPONENTS QWindowsIntegrationPlugin)
 	list(APPEND QT_PLUGIN_PLATFORM_DEFINITIONS -DQT_QPA_PLATFORM_WINDOWS=1)
 
 	target_sources(bitcoin-qt-base PRIVATE winshutdownmonitor.cpp)
 endif()
 
 # OSX support
 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 	list(APPEND QT_PLUGIN_COMPONENTS QCocoaIntegrationPlugin)
 	list(APPEND QT_PLUGIN_PLATFORM_DEFINITIONS -DQT_QPA_PLATFORM_COCOA=1)
 
 	target_sources(bitcoin-qt-base PRIVATE
 		macdockiconhandler.mm
 		macnotificationhandler.mm
 	)
 
 	set_property(TARGET bitcoin-qt-base PROPERTY AUTOMOC_MOC_OPTIONS "-DQ_OS_MAC")
 
 	target_link_libraries(bitcoin-qt-base
 		"-framework Foundation"
 		"-framework ApplicationServices"
 		"-framework AppKit"
 	)
 endif()
 
 # Find out more about Qt. This is similar to
 # http://code.qt.io/cgit/qt/qtwebkit.git/tree/Source/cmake/OptionsQt.cmake
 get_target_property(QT_CORE_TYPE Qt5::Core TYPE)
 if(QT_CORE_TYPE MATCHES STATIC)
 	set(QT_STATIC_BUILD ON)
 endif()
 
 # Determine the Qt libraries directory from the QT5::Core library location
 get_target_property(QT_CORE_LIB_LOCATION Qt5::Core LOCATION)
 get_filename_component(QT5_LIB_DIR "${QT_CORE_LIB_LOCATION}" DIRECTORY)
 
 set(STATIC_DEPENDENCIES_CMAKE_FILE "${CMAKE_BINARY_DIR}/QtStaticDependencies.cmake")
 if(EXISTS ${STATIC_DEPENDENCIES_CMAKE_FILE})
 	file(REMOVE ${STATIC_DEPENDENCIES_CMAKE_FILE})
 endif()
 
 set(CONVERT_PRL_PATH "${CONTRIB_PATH}/qt/convert-prl-libs-to-cmake.pl")
 macro(CONVERT_PRL_LIBS_TO_CMAKE _qt_component)
 	if(TARGET Qt5::${_qt_component})
 		get_target_property(_lib_location Qt5::${_qt_component} LOCATION)
 		execute_process(COMMAND ${PERL_EXECUTABLE} "${CONVERT_PRL_PATH}"
 			--lib "${_lib_location}"
 			--qt_lib_install_dir "${QT5_LIB_DIR}"
 			--out "${STATIC_DEPENDENCIES_CMAKE_FILE}"
 			--component "${_qt_component}"
 			--compiler "${CMAKE_CXX_COMPILER_ID}"
 		)
 	endif()
 endmacro()
 
 if(QT_STATIC_BUILD)
 	list(APPEND QT_REQUIRED_COMPONENTS ${QT_PLUGIN_COMPONENTS})
 
 	foreach(qt_module ${QT_REQUIRED_COMPONENTS})
 		CONVERT_PRL_LIBS_TO_CMAKE(${qt_module})
 	endforeach()
 
 	# HACK: We must explicitly add LIB path of the Qt installation
 	# to correctly find qtpcre
 	link_directories("${QT5_LIB_DIR}")
 
 	# Now that we generated the dependencies, import them.
 	set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS "${CONVERT_PRL_PATH}")
 	if(NOT EXISTS ${STATIC_DEPENDENCIES_CMAKE_FILE})
 		message(FATAL_ERROR "Unable to find ${STATIC_DEPENDENCIES_CMAKE_FILE}")
 	endif()
 	include(${STATIC_DEPENDENCIES_CMAKE_FILE})
 	list(REMOVE_DUPLICATES STATIC_LIB_DEPENDENCIES)
 
 	# According to Qt documentation (https://doc.qt.io/qt-5/plugins-howto.html):
 	# "Plugins can be linked statically into your application.
 	# If you build the static version of Qt, this is the only option for
 	# including Qt's predefined plugins."
 	# So if the Qt build is static, the plugins should also be static and we
 	# need to define QT_STATICPLUGIN to tell the code to import <QTPlugin>.
 	target_compile_definitions(bitcoin-qt-base PUBLIC -DQT_STATICPLUGIN=1)
 
 	# Add the platform plugin definition if required
 	# Setting this definition tells the code what is the target for Q_IMPORT_PLUGIN().
 	foreach(qt_platform_definition ${QT_PLUGIN_PLATFORM_DEFINITIONS})
 		target_compile_definitions(bitcoin-qt-base PUBLIC "${qt_platform_definition}")
 	endforeach()
 
 	# Link the required plugins
 	foreach(qt_plugin ${QT_PLUGIN_COMPONENTS})
 		target_link_libraries(bitcoin-qt-base Qt5::${qt_plugin})
 	endforeach()
 endif()
 
 target_link_libraries(bitcoin-qt-base
 	server
 	rpcclient
 	Qt5::Widgets
 	Qt5::Network
 )
 if(ENABLE_DBUS_NOTIFICATIONS)
 	target_link_libraries(bitcoin-qt-base Qt5::DBus)
 endif()
 
 if(ENABLE_BIP70)
 	# Do protobuf codegen
 	find_package(Protobuf REQUIRED)
 	protobuf_generate_cpp(PROTOBUF_SOURCES PROTOBUF_HEADERS paymentrequest.proto)
 
 	add_library(bitcoin-qt-protobuf OBJECT
 		# Protobuf codegen
 			${PROTOBUF_HEADERS}
 			${PROTOBUF_SOURCES}
 	)
 
 	target_include_directories(bitcoin-qt-protobuf PUBLIC ${Protobuf_INCLUDE_DIRS})
 	target_link_libraries(bitcoin-qt-protobuf ${Protobuf_LIBRARIES})
 
 	# Don't run clang-tidy on generated files
 	if(ENABLE_CLANG_TIDY)
 		include(ClangTidy)
 		target_disable_clang_tidy(bitcoin-qt-protobuf)
 	endif()
 
 	# Message::ByteSize() is deprecated and replaced by ByteSizeLong() since
 	# protobuf 3.1.
 	if(Protobuf_VERSION GREATER_EQUAL "3.1.0")
 		target_compile_definitions(bitcoin-qt-base PRIVATE USE_PROTOBUF_MESSAGE_BYTESIZELONG)
 	endif()
 
 	# OpenSSL functionality
 	include(BrewHelper)
 	find_brew_prefix(OPENSSL_ROOT_DIR openssl)
 	find_package(OpenSSL REQUIRED)
 
 	include(CheckSymbolExists)
 	set(CMAKE_REQUIRED_INCLUDES ${OPENSSL_INCLUDE_DIR})
 	set(CMAKE_REQUIRED_LIBRARIES ${OPENSSL_CRYPTO_LIBRARY})
 	check_symbol_exists(EVP_MD_CTX_new "openssl/evp.h" HAVE_DECL_EVP_MD_CTX_NEW)
 	if(HAVE_DECL_EVP_MD_CTX_NEW)
 		target_compile_definitions(bitcoin-qt-base PRIVATE HAVE_DECL_EVP_MD_CTX_NEW=1)
 	endif()
 
 	target_link_libraries(bitcoin-qt-base
 		OpenSSL::SSL
 		bitcoin-qt-protobuf
 	)
 endif()
 
 # Wallet
 if(BUILD_BITCOIN_WALLET)
 	# Automoc option.
 	set(AUTOMOC_MOC_OPTIONS -DENABLE_WALLET=1)
 
 	# Add wallet functionality to bitcoin-qt
 	target_sources(bitcoin-qt-base
 		PRIVATE
 			addressbookpage.cpp
 			addresstablemodel.cpp
 			askpassphrasedialog.cpp
 			coincontroldialog.cpp
 			coincontroltreewidget.cpp
 			createwalletdialog.cpp
 			editaddressdialog.cpp
 			openuridialog.cpp
 			overviewpage.cpp
 			paymentserver.cpp
 			receivecoinsdialog.cpp
 			receiverequestdialog.cpp
 			recentrequeststablemodel.cpp
 			sendcoinsdialog.cpp
 			sendcoinsentry.cpp
 			signverifymessagedialog.cpp
 			transactiondesc.cpp
 			transactiondescdialog.cpp
 			transactionfilterproxy.cpp
 			transactionrecord.cpp
 			transactiontablemodel.cpp
 			transactionview.cpp
 			walletcontroller.cpp
 			walletframe.cpp
 			walletmodel.cpp
 			walletmodeltransaction.cpp
 			walletview.cpp
 	)
 
 	# Add BIP70 functionality to bitcoin-qt
 	if(ENABLE_BIP70)
 		target_sources(bitcoin-qt-base
 			PRIVATE
 				paymentrequestplus.cpp
 		)
 	endif()
 
 	target_link_libraries(bitcoin-qt-base wallet)
 
 	if(ENABLE_QRCODE)
 		find_package(QREncode REQUIRED)
 		target_link_libraries(bitcoin-qt-base QREncode::qrencode)
 	endif()
 endif()
 
 # The executable
 add_executable(bitcoin-qt WIN32 main.cpp)
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	target_sources(bitcoin-qt PRIVATE res/bitcoin-qt-res.rc)
 endif()
 target_link_libraries(bitcoin-qt bitcoin-qt-base)
 
 include(BinaryTest)
 add_to_symbols_check(bitcoin-qt)
 add_to_security_check(bitcoin-qt)
 
 include(InstallationHelper)
 install_target(bitcoin-qt)
-install_manpage(bitcoin-qt)
+install_manpages(bitcoin-qt)
 
 if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 	set(BITCOINQT_BUNDLE_ICON "res/icons/bitcoin.icns")
 	get_filename_component(BITCOINQT_BUNDLE_ICON_NAME
 		"${BITCOINQT_BUNDLE_ICON}"
 		NAME
 	)
 
 	set(INFO_PLIST_STRINGS_FILE "Base.lproj/InfoPlist.strings")
 	set(INFO_PLIST_STRINGS_PATH "${CMAKE_CURRENT_BINARY_DIR}/${INFO_PLIST_STRINGS_FILE}")
 	file(WRITE
 		"${INFO_PLIST_STRINGS_PATH}"
 		"{	CFBundleDisplayName = \"${PACKAGE_NAME}\"; CFBundleName = \"${PACKAGE_NAME}\"; }"
 	)
 
 	set(EMPTY_LPROJ_FILE "${CMAKE_CURRENT_BINARY_DIR}/empty.lproj")
 	file(TOUCH "${EMPTY_LPROJ_FILE}")
 
 	target_sources(bitcoin-qt PRIVATE
 		"${BITCOINQT_BUNDLE_ICON}"
 		"${INFO_PLIST_STRINGS_PATH}"
 		"${EMPTY_LPROJ_FILE}"
 	)
 
 	string(JOIN ";" BITCOINQT_BUNDLE_RESOURCES
 		"${BITCOINQT_BUNDLE_ICON}"
 		"${EMPTY_LPROJ_FILE}"
 	)
 
 	set(BITCOIN_QT_OSX_BUNDLE_NAME "BitcoinABC-Qt")
 	set_target_properties(bitcoin-qt PROPERTIES
 		MACOSX_BUNDLE ON
 		OUTPUT_NAME "${BITCOIN_QT_OSX_BUNDLE_NAME}"
 		MACOSX_BUNDLE_INFO_PLIST "${CMAKE_SOURCE_DIR}/share/qt/Info.plist.cmake.in"
 		MACOSX_BUNDLE_BUNDLE_NAME "${BITCOIN_QT_OSX_BUNDLE_NAME}"
 		MACOSX_BUNDLE_BUNDLE_VERSION "${bitcoin-abc_VERSION}"
 		MACOSX_BUNDLE_GUI_IDENTIFIER "org.bitcoinabc.${BITCOIN_QT_OSX_BUNDLE_NAME}"
 		MACOSX_BUNDLE_ICON_FILE "${BITCOINQT_BUNDLE_ICON_NAME}"
 		MACOSX_BUNDLE_INFO_STRING "${bitcoin-abc_VERSION}, Copyright © 2009-${COPYRIGHT_YEAR} ${COPYRIGHT_HOLDERS_FINAL}"
 		MACOSX_BUNDLE_LONG_VERSION_STRING "${bitcoin-abc_VERSION}"
 		MACOSX_BUNDLE_SHORT_VERSION_STRING "${bitcoin-abc_VERSION}"
 		RESOURCE "${BITCOINQT_BUNDLE_RESOURCES}"
 	)
 	# The InfoPlist.strings files should be located in a resource subdirectory.
 	# This is not supported by the RESOURCE property and require the use of the
 	# MACOSX_PACKAGE_LOCATION property instead. The RESOURCE documentation has
 	# an example demonstrating this behavior (see the appres.txt file):
 	# https://cmake.org/cmake/help/latest/prop_tgt/RESOURCE.html
 	set_source_files_properties(
 		"${INFO_PLIST_STRINGS_PATH}"
 		PROPERTIES
 			MACOSX_PACKAGE_LOCATION "Resources/${INFO_PLIST_STRINGS_FILE}"
 	)
 
 	# Create a stripped version of the application bundle to be used in the DMG.
 	# Since the LOCATION property and the BundleUtilities package are deprecated
 	# by cmake, only generator expressions can be used to determine the path to
 	# the bundle and its executable. However the generator expressions are
 	# solved at build time, making them unusable to do path computation at
 	# configuration time.
 	# The paths here are then hard-coded, which is safe since the structure of
 	# an application bundle is well-known and specified by Apple. Note that this
 	# will only work for building MacOS application bundle as the IOS structure
 	# is slightly different.
 	set(STRIPPED_BUNDLE "${CMAKE_CURRENT_BINARY_DIR}/stripped/${BITCOIN_QT_OSX_BUNDLE_NAME}.app")
 	add_custom_command(
 		OUTPUT
 			"${STRIPPED_BUNDLE}"
 		COMMAND
 			${CMAKE_COMMAND} -E copy_directory "$<TARGET_BUNDLE_DIR:bitcoin-qt>" "${STRIPPED_BUNDLE}"
 		COMMAND
 			${CMAKE_STRIP} -u -r "${STRIPPED_BUNDLE}/Contents/MacOS/${BITCOIN_QT_OSX_BUNDLE_NAME}"
 		DEPENDS
 			bitcoin-qt
 	)
 
 	include(DoOrFail)
 	find_program_or_fail(CMAKE_INSTALL_NAME_TOOL "install_name_tool")
 	find_program_or_fail(CMAKE_OTOOL "otool")
 
 	set(QT_INSTALLER_SUPPORTED_LANGUAGES
 		"da"
 		"de"
 		"es"
 		"hu"
 		"ru"
 		"uk"
 		"zh_CN"
 		"zh_TW"
 	)
 	string(JOIN "," QT_LOCALES ${QT_INSTALLER_SUPPORTED_LANGUAGES})
 
 	get_target_property(QMAKE_EXECUTABLE Qt5::qmake IMPORTED_LOCATION)
 	execute_process(
 		COMMAND
 			"${QMAKE_EXECUTABLE}"
 			-query QT_INSTALL_TRANSLATIONS
 		OUTPUT_VARIABLE
 			QT_TRANSLATION_DIR
 		OUTPUT_STRIP_TRAILING_WHITESPACE
 	)
 
 	function(get_qt_translation_dir QT_TRANSLATION_DIR)
 		foreach(_locale ${ARGN})
 			find_path(_qt_translation_dir
 				"qt_${_locale}.qm"
 				HINTS
 					"${QT_TRANSLATION_DIR}"
 				PATH_SUFFIXES
 					"translations"
 			)
 
 			# Ensure that all the translation files are found, and are located
 			# in the same directory.
 			if(NOT _qt_translation_dir OR (_qt_translation_dir_previous AND (NOT _qt_translation_dir_previous STREQUAL _qt_translation_dir)))
 				return()
 			endif()
 
 			set(_qt_translation_dir_previous _qt_translation_dir)
 		endforeach()
 
 		set(QT_TRANSLATION_DIR ${_qt_translation_dir} PARENT_SCOPE)
 	endfunction()
 
 	get_qt_translation_dir(QT_TRANSLATION_DIR ${QT_INSTALLER_SUPPORTED_LANGUAGES})
 	if(NOT QT_TRANSLATION_DIR)
 		message(FATAL_ERROR "Qt translation files are not found")
 	endif()
 
 	set(MACDEPLOY_DIR "${CMAKE_SOURCE_DIR}/contrib/macdeploy")
 	set(MACDEPLOYQTPLUS "${MACDEPLOY_DIR}/macdeployqtplus")
 	set(DMG_DIST "${CMAKE_BINARY_DIR}/dist")
 	add_custom_command(
 		OUTPUT
 			"${DMG_DIST}"
 		COMMAND
 			"INSTALLNAMETOOL=${CMAKE_INSTALL_NAME_TOOL}"
 			"OTOOL=${CMAKE_OTOOL}"
 			"STRIP=${CMAKE_STRIP}"
 			"${Python_EXECUTABLE}"
 			"${MACDEPLOYQTPLUS}"
 			"${STRIPPED_BUNDLE}"
 			-translations-dir "${QT_TRANSLATION_DIR}"
 			-add-qt-tr "${QT_LOCALES}"
 		WORKING_DIRECTORY
 			"${CMAKE_BINARY_DIR}"
 		DEPENDS
 			"${STRIPPED_BUNDLE}"
 	)
 
 	# Building the DMG background image requires several steps:
 	#   1/ The SVG file must be edited to display the package name
 	#   2/ The SVG file should be transformed into a couple PNG files, on for
 	#      low resolution screens and one for high resolution screens.
 	#   3/ The PNG files must be transformed into a multi-resolution TIFF file.
 	#      The names are not set arbitrarily, they follow Apple's guidelines for
 	#      resolution independent bitmap images (see `man tiffutil`).
 	set(BACKGROUND_SVG "background.svg")
 	configure_file(
 		"${CMAKE_SOURCE_DIR}/contrib/macdeploy/background.svg.cmake.in"
 		"${BACKGROUND_SVG}"
 	)
 
 	include(ImageHelper)
 	set(BACKGROUND_PNG_LOWRES "${CMAKE_CURRENT_BINARY_DIR}/background_temp.png")
 	set(BACKGROUND_PNG_HIRES "${CMAKE_CURRENT_BINARY_DIR}/background_temp@2x.png")
 	set(BACKGROUND_TIFF_LOWRES "${CMAKE_CURRENT_BINARY_DIR}/background_temp.tiff")
 	set(BACKGROUND_TIFF_HIRES "${CMAKE_CURRENT_BINARY_DIR}/background_temp@2x.tiff")
 	set(BACKGROUND_TIFF_NAME "background.tiff")
 	set(BACKGROUND_TIFF_MULTIRES "${CMAKE_BINARY_DIR}/${BACKGROUND_TIFF_NAME}")
 	convert_svg_to_png("${BACKGROUND_SVG}" "${BACKGROUND_PNG_LOWRES}" 36)
 	convert_svg_to_png("${BACKGROUND_SVG}" "${BACKGROUND_PNG_HIRES}" 72)
 	convert_png_to_tiff("${BACKGROUND_PNG_LOWRES}" "${BACKGROUND_TIFF_LOWRES}")
 	convert_png_to_tiff("${BACKGROUND_PNG_HIRES}" "${BACKGROUND_TIFF_HIRES}")
 	cat_multi_resolution_tiff("${BACKGROUND_TIFF_MULTIRES}" "${BACKGROUND_TIFF_LOWRES}" "${BACKGROUND_TIFF_HIRES}")
 
 	set(BACKGROUND_DIST_DIR "${DMG_DIST}/.background")
 	set(BACKGROUND_DIST_TIFF "${BACKGROUND_DIST_DIR}/${BACKGROUND_TIFF_NAME}")
 	add_custom_command(
 		OUTPUT
 			"${BACKGROUND_DIST_TIFF}"
 		COMMAND
 			${CMAKE_COMMAND} -E make_directory "${BACKGROUND_DIST_DIR}"
 		COMMAND
 			${CMAKE_COMMAND} -E copy "${BACKGROUND_TIFF_MULTIRES}" "${BACKGROUND_DIST_TIFF}"
 		DEPENDS
 			"${BACKGROUND_TIFF_MULTIRES}"
 			"${DMG_DIST}"
 	)
 
 	string(REPLACE " " "-" OSX_VOLNAME "${PACKAGE_NAME}")
 	file(WRITE "${CMAKE_BINARY_DIR}/osx_volname" "${OSX_VOLNAME}")
 
 	set(DMG_DSSTORE "${DMG_DIST}/.DS_Store")
 	set(GEN_DSSTORE "${MACDEPLOY_DIR}/custom_dsstore.py")
 	add_custom_command(
 		OUTPUT
 			"${DMG_DSSTORE}"
 		COMMAND
 			"${Python_EXECUTABLE}"
 			"${GEN_DSSTORE}"
 			"${DMG_DSSTORE}"
 			"${OSX_VOLNAME}"
 		DEPENDS
 			"${GEN_DSSTORE}"
 			"${DMG_DIST}"
 	)
 
 	set(OSX_APPLICATION_DIR "Applications")
 	set(OSX_APPLICATION_SYMLINK "${DMG_DIST}/${OSX_APPLICATION_DIR}")
 	add_custom_command(
 		OUTPUT
 			"${OSX_APPLICATION_SYMLINK}"
 		COMMAND
 			${CMAKE_COMMAND} -E create_symlink "/${OSX_APPLICATION_DIR}" "${OSX_APPLICATION_SYMLINK}"
 		DEPENDS
 			"${DMG_DIST}"
 	)
 
 	add_custom_target(osx-deploydir
 		DEPENDS
 			"${OSX_APPLICATION_SYMLINK}"
 			"${DMG_DSSTORE}"
 			"${BACKGROUND_DIST_TIFF}"
 	)
 
 	if(CMAKE_CROSSCOMPILING)
 		find_program_or_fail(GENISOIMAGE_EXECUTABLE genisoimage)
 
 		add_custom_target(osx-dmg
 			COMMAND
 				"${GENISOIMAGE_EXECUTABLE}"
 				-no-cache-inodes
 				-D
 				-l
 				-probe
 				-V "${OSX_VOLNAME}"
 				-no-pad
 				-r
 				-dir-mode 0755
 				-apple
 				-o "${OSX_VOLNAME}.dmg"
 				"${DMG_DIST}"
 			WORKING_DIRECTORY
 				"${CMAKE_BINARY_DIR}"
 		)
 		add_dependencies(osx-dmg osx-deploydir)
 	else()
 		add_custom_target(osx-dmg
 			COMMAND
 				"${Python_EXECUTABLE}"
 				"${MACDEPLOYQTPLUS}"
 				"${STRIPPED_BUNDLE}"
 				-translations-dir "${QT_TRANSLATION_DIR}"
 				-add-qt-tr "${QT_LOCALES}"
 				-dmg
 				-fancy "${MACDEPLOY_DIR}/fancy.plist"
 				-volname "${OSX_VOLNAME}"
 			WORKING_DIRECTORY
 				"${CMAKE_BINARY_DIR}"
 			DEPENDS
 				"${STRIPPED_BUNDLE}"
 				"${BACKGROUND_TIFF_MULTIRES}"
 		)
 	endif()
 endif()
 
 configure_file(
 	"${CMAKE_SOURCE_DIR}/cmake/utils/translate.sh.in"
 	"${CMAKE_CURRENT_BINARY_DIR}/translate.sh"
 	@ONLY
 )
 
 add_custom_target(translate
 	COMMENT "Updating the translations..."
 	COMMAND "${CMAKE_CURRENT_BINARY_DIR}/translate.sh"
 	DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/translate.sh"
 	WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/.."
 )
 
 # Test tests
 add_subdirectory(test)