diff --git a/CMakeLists.txt b/CMakeLists.txt
index 1685f0a7c..0146ae477 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,129 +1,129 @@
 # Copyright (c) 2017 The Bitcoin developers
 
 cmake_minimum_required(VERSION 3.16)
 
 set(CMAKE_USER_MAKE_RULES_OVERRIDE
 	"${CMAKE_SOURCE_DIR}/cmake/modules/OverrideInitFlags.cmake"
 )
 
 project(bitcoin-abc
 	VERSION 0.22.13
-	DESCRIPTION "Bitcoin ABC is a full node implementation of the Bitcoin Cash protocol."
+	DESCRIPTION "Bitcoin ABC is a full node implementation of the BCHA protocol."
 	HOMEPAGE_URL "https://www.bitcoinabc.org"
 )
 
 add_custom_target(print-version
   COMMENT "Print the current ${PROJECT_NAME} version"
   COMMAND "${CMAKE_COMMAND}" -E echo "${PROJECT_VERSION}"
 )
 
 # Package information
 set(PACKAGE_NAME "Bitcoin ABC")
 set(PACKAGE_BUGREPORT "https://github.com/Bitcoin-ABC/bitcoin-abc/issues")
 
 # Copyright
 set(COPYRIGHT_YEAR 2021)
 set(COPYRIGHT_HOLDERS "The %s developers")
 set(COPYRIGHT_HOLDERS_SUBSTITUTION Bitcoin)
 string(REPLACE "%s" ${COPYRIGHT_HOLDERS_SUBSTITUTION} COPYRIGHT_HOLDERS_FINAL ${COPYRIGHT_HOLDERS})
 
 # Add path for custom modules
 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules)
 
 # Make contrib script accessible.
 set(CONTRIB_PATH ${CMAKE_CURRENT_SOURCE_DIR}/contrib)
 
 # Default to RelWithDebInfo configuration
 if(NOT CMAKE_BUILD_TYPE)
 	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
 		"Select the configuration for the build" FORCE)
 	set(__NO_USER_CMAKE_BUILD_TYPE ON CACHE BOOL "True if the user didn't set a build type on the command line")
 endif()
 
 # Find the python interpreter. This is required for several targets.
 find_package(Python 3.5 COMPONENTS Interpreter REQUIRED)
 
 # Add the magic targets `check-*`
 add_custom_target(check-all)
 add_custom_target(check)
 add_custom_target(check-extended)
 add_custom_target(check-upgrade-activated)
 add_custom_target(check-upgrade-activated-extended)
 
 # Add the global install targets
 add_custom_target(install-all)
 add_custom_target(install-debug)
 add_custom_target(install-all-debug)
 
 include(PackageHelper)
 exclude_git_ignored_files_from_source_package()
 
 # Ignore hidden files and directories (starting with a '.')
 set_property(GLOBAL APPEND PROPERTY SOURCE_PACKAGE_IGNORE_FILES	"/\\\\.")
 
 # If the build is out-of-tree, then the build directory can be ignored.
 if(NOT CMAKE_BINARY_DIR STREQUAL CMAKE_SOURCE_DIR)
 	set_property(GLOBAL APPEND PROPERTY SOURCE_PACKAGE_IGNORE_FILES
 		"${CMAKE_BINARY_DIR}/"
 	)
 endif()
 
 exclude_from_source_package(
 	# Subdirectories
 	"arcanist/"
 	"depends/"
 
 	# Files
 	"[^.]+[.]md$"
 )
 
 option(ENABLE_COVERAGE "Enable coverage" OFF)
 option(ENABLE_BRANCH_COVERAGE "Enable branch coverage" OFF)
 
 if(ENABLE_COVERAGE)
 	include(Coverage)
 	enable_coverage(${ENABLE_BRANCH_COVERAGE})
 
 	include(AddCompilerFlags)
 
 	# If no build type is manually defined, override the optimization level.
 	# Otherwise, alert the user than the coverage result might be useless.
 	if(__NO_USER_CMAKE_BUILD_TYPE)
 		set_c_optimization_level(0)
 
 		# Setting -Og instead of -O0 is a workaround for the GCC bug 90380:
 		# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=90380
 		#
 		# This bug is fixed upstream, but is not widely distributed yet.
 		# Fixed in GCC versions:
 		#  - GCC 7.x: versions <= 7.2 are unaffected
 		#  - GCC 8.x: versions >= 8.3.1
 		#  - GCC 9.x: versions >= 9.1.1
 		#  - GCC 10.x: all versions
 		set_cxx_optimization_level(g)
 	else()
 		message(WARNING "It is advised to not enforce CMAKE_BUILD_TYPE to get the best coverage results")
 	endif()
 
 	exclude_from_coverage(
 		"depends"
 		"src/bench"
 		"src/crypto/ctaes"
 		"src/leveldb"
 		"src/univalue"
 	)
 
 	add_custom_target_coverage(check)
 	add_custom_target_coverage(check-all)
 	add_custom_target_coverage(check-extended)
 	add_custom_target_coverage(check-upgrade-activated)
 	add_custom_target_coverage(check-upgrade-activated-extended)
 endif()
 
 add_subdirectory(src)
 add_subdirectory(test)
 
 add_subdirectory(contrib)
 add_subdirectory(doc)
 
 include(PackageOptions.cmake)
diff --git a/PackageOptions.cmake b/PackageOptions.cmake
index ad57ae4b5..bba324020 100644
--- a/PackageOptions.cmake
+++ b/PackageOptions.cmake
@@ -1,69 +1,69 @@
 # Package options
 set(CPACK_PACKAGE_VENDOR "${COPYRIGHT_HOLDERS_FINAL}")
-set(CPACK_PACKAGE_DESCRIPTION "Bitcoin ABC is a Bitcoin Cash full node implementation.")
+set(CPACK_PACKAGE_DESCRIPTION "${PROJECT_DESCRIPTION}")
 set(CPACK_PACKAGE_HOMEPAGE_URL "${PROJECT_HOMEPAGE_URL}")
 set(CPACK_PACKAGE_CONTACT "info@bitcoinabc.org")
 
 set(CPACK_PACKAGE_INSTALL_DIRECTORY "Bitcoin-abc")
 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/doc/README_windows.txt")
 
 if(CMAKE_CROSSCOMPILING)
 	set(CPACK_SYSTEM_NAME "${TOOLCHAIN_PREFIX}")
 endif()
 
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	set(CPACK_PACKAGE_ICON "${CMAKE_SOURCE_DIR}/share/pixmaps/nsis-header.bmp")
 	set(CPACK_GENERATOR "NSIS;ZIP")
 	set(CPACK_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR}/doc" doc)
 else()
 	set(CPACK_PACKAGE_ICON "${CMAKE_SOURCE_DIR}/share/pixmaps/bitcoin-abc128.png")
 	set(CPACK_GENERATOR "TGZ")
 endif()
 
 # Prevent the components aware generators (such as ZIP) from generating a
 # different package for each component.
 set(CPACK_MONOLITHIC_INSTALL ON)
 
 # CPack source package options
 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${PROJECT_NAME}-${PROJECT_VERSION}")
 set(CPACK_SOURCE_GENERATOR "TGZ")
 
 # CPack NSIS installer options
 Include(InstallationHelper)
 set(CPACK_NSIS_EXECUTABLES_DIRECTORY "${CMAKE_INSTALL_BINDIR}")
 set(_nsis_bitcoin_qt "bitcoin-qt.exe")
 
 set(CPACK_NSIS_URL_INFO_ABOUT "${CPACK_PACKAGE_HOMEPAGE_URL}")
 set(CPACK_NSIS_CONTACT "${CPACK_PACKAGE_CONTACT}")
 
 set(CPACK_NSIS_MUI_ICON "${CMAKE_SOURCE_DIR}/share/pixmaps/bitcoin-abc.ico")
 set(CPACK_NSIS_MUI_UNIICON "${CPACK_NSIS_MUI_ICON}")
 set(CPACK_NSIS_MUI_WELCOMEFINISHPAGE_BITMAP "${CMAKE_SOURCE_DIR}/share/pixmaps/nsis-wizard.bmp")
 set(CPACK_NSIS_MUI_UNWELCOMEFINISHPAGE_BITMAP "${CPACK_NSIS_MUI_WELCOMEFINISHPAGE_BITMAP}")
 set(CPACK_NSIS_MUI_FINISHPAGE_RUN "${_nsis_bitcoin_qt}")
 set(CPACK_NSIS_INSTALLED_ICON_NAME "${CMAKE_INSTALL_BINDIR}/${_nsis_bitcoin_qt}")
 
 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma")
 set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL ON)
 set(CPACK_NSIS_DISPLAY_NAME "${PACKAGE_NAME}")
 
 macro(add_start_menu_link LINK_NAME EXE PARAMETERS ICON_EXE ICON_INDEX)
 	list(APPEND CPACK_NSIS_CREATE_ICONS_EXTRA
 		"CreateShortCut '$SMPROGRAMS\\\\$STARTMENU_FOLDER\\\\${LINK_NAME}.lnk' '$INSTDIR\\\\${CMAKE_INSTALL_BINDIR}\\\\${EXE}' '${PARAMETERS}' '$INSTDIR\\\\${CMAKE_INSTALL_BINDIR}\\\\${ICON_EXE}' '${ICON_INDEX}'"
 	)
 	list(APPEND CPACK_NSIS_DELETE_ICONS_EXTRA
 		"Delete '$SMPROGRAMS\\\\$START_MENU\\\\${LINK_NAME}.lnk'"
 	)
 endmacro()
 
 set(CPACK_NSIS_MENU_LINKS "${CMAKE_INSTALL_BINDIR}/${_nsis_bitcoin_qt}" "Bitcoin ABC")
 add_start_menu_link("${PACKAGE_NAME} (testnet)"
 	"${_nsis_bitcoin_qt}"
 	"-testnet"
 	"${_nsis_bitcoin_qt}"
 	1
 )
 
 get_property(CPACK_SOURCE_IGNORE_FILES GLOBAL PROPERTY SOURCE_PACKAGE_IGNORE_FILES)
 include(CPack)