diff --git a/cmake/modules/TestSuite.cmake b/cmake/modules/TestSuite.cmake
index 0729765a7..b9881b071 100644
--- a/cmake/modules/TestSuite.cmake
+++ b/cmake/modules/TestSuite.cmake
@@ -1,159 +1,161 @@
 # Allow to easily build test suites
 
 option(ENABLE_JUNIT_REPORT "Enable Junit report generation for targets that support it" OFF)
 
+set(JUNIT_REPORT_DIRECTORY "${CMAKE_BINARY_DIR}/test/junit")
 set_property(
 	DIRECTORY "${CMAKE_SOURCE_DIR}"
 	APPEND PROPERTY ADDITIONAL_CLEAN_FILES
-		"${CMAKE_BINARY_DIR}/test/junit"
+		"${JUNIT_REPORT_DIRECTORY}"
 		"${CMAKE_BINARY_DIR}/test/tmp"
 )
 
 macro(add_test_environment VARIABLE VALUE)
 	set_property(GLOBAL APPEND PROPERTY TEST_ENVIRONMENT "${VARIABLE}=${VALUE}")
 endmacro()
 
 function(add_test_custom_target TARGET)
 	cmake_parse_arguments(ARG "" "" "CUSTOM_TARGET_ARGS;TEST_COMMAND" ${ARGN})
 
 	get_property(TEST_ENVIRONMENT GLOBAL PROPERTY TEST_ENVIRONMENT)
 
 	add_custom_target(${TARGET}
 		${ARG_CUSTOM_TARGET_ARGS}
+		COMMAND ${CMAKE_COMMAND} -E make_directory "${JUNIT_REPORT_DIRECTORY}"
 		COMMAND ${CMAKE_COMMAND} -E env ${TEST_ENVIRONMENT} ${ARG_TEST_COMMAND}
 	)
 endfunction()
 
 # Define a new target property to hold the list of tests associated with a test
 # suite. This property is named UNIT_TESTS to avoid confusion with the directory
 # level property TESTS.
 define_property(TARGET
 	PROPERTY UNIT_TESTS
 	BRIEF_DOCS "List of tests"
 	FULL_DOCS "A list of the tests associated with a test suite"
 )
 
 macro(get_target_from_suite SUITE TARGET)
 	set(${TARGET} "check-${SUITE}")
 endmacro()
 
 include(Coverage)
 
 function(create_test_suite_with_parent_targets NAME)
 	get_target_from_suite(${NAME} TARGET)
 
 	add_custom_target(${TARGET}
 		COMMENT "Running ${NAME} test suite"
 		COMMAND cmake -E echo "PASSED: ${NAME} test suite"
 	)
 
 	foreach(PARENT_TARGET ${ARGN})
 		if(TARGET ${PARENT_TARGET})
 			add_dependencies(${PARENT_TARGET} ${TARGET})
 		endif()
 	endforeach()
 
 	add_custom_target_coverage(${TARGET})
 endfunction()
 
 macro(create_test_suite NAME)
 	create_test_suite_with_parent_targets(${NAME} check-all check-extended)
 endmacro()
 
 set(TEST_RUNNER_TEMPLATE "${CMAKE_CURRENT_LIST_DIR}/../templates/TestRunner.cmake.in")
 function(add_test_runner SUITE NAME EXECUTABLE)
 	cmake_parse_arguments(ARG "JUNIT" "" "" ${ARGN})
 
 	get_target_from_suite(${SUITE} SUITE_TARGET)
 	set(TARGET "${SUITE_TARGET}-${NAME}")
 
 	add_test_custom_target(${TARGET}
 		TEST_COMMAND
 			"${CMAKE_SOURCE_DIR}/cmake/utils/test_wrapper.sh"
 			"${SUITE}-${NAME}.log"
 			${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${EXECUTABLE}>" ${ARG_UNPARSED_ARGUMENTS}
 		CUSTOM_TARGET_ARGS
 			COMMENT "${SUITE}: testing ${NAME}"
 			DEPENDS ${EXECUTABLE}
 			VERBATIM
 	)
 	add_dependencies(${SUITE_TARGET} ${TARGET})
 
 	if(ENABLE_JUNIT_REPORT AND ARG_JUNIT)
 		add_custom_command(TARGET ${TARGET} POST_BUILD
 			COMMENT "Processing junit report for test ${NAME} from suite ${SUITE}"
 			COMMAND_EXPAND_LISTS
 			COMMAND
 				"${Python_EXECUTABLE}" "${CMAKE_SOURCE_DIR}/cmake/utils/junit-reports-merge.py"
-				"${CMAKE_BINARY_DIR}/test/junit"
+				"${JUNIT_REPORT_DIRECTORY}"
 				"${CMAKE_BINARY_DIR}/test/tmp"
 				"${SUITE}"
 				"${NAME}"
 		)
 	endif()
 endfunction()
 
 function(add_test_to_suite SUITE NAME)
 	add_executable(${NAME} EXCLUDE_FROM_ALL ${ARGN})
 	add_test_runner(${SUITE} ${NAME} ${NAME})
 
 	get_target_from_suite(${SUITE} TARGET)
 	set_property(
 		TARGET ${TARGET}
 		APPEND PROPERTY UNIT_TESTS ${NAME}
 	)
 endfunction(add_test_to_suite)
 
 function(add_boost_unit_tests_to_suite SUITE NAME)
 	cmake_parse_arguments(ARG
 		""
 		""
 		"TESTS"
 		${ARGN}
 	)
 
 	get_target_from_suite(${SUITE} SUITE_TARGET)
 	add_executable(${NAME} EXCLUDE_FROM_ALL ${ARG_UNPARSED_ARGUMENTS})
 	add_dependencies("${SUITE_TARGET}" ${NAME})
 
 	set(HRF_LOGGER "HRF,test_suite")
 
 	foreach(_test_source ${ARG_TESTS})
 		target_sources(${NAME} PRIVATE "${_test_source}")
 		get_filename_component(_test_name "${_test_source}" NAME_WE)
 
 		if(ENABLE_JUNIT_REPORT)
 			set(JUNIT_LOGGER ":JUNIT,message,${SUITE}-${_test_name}.xml")
 		endif()
 
 		add_test_runner(
 			${SUITE}
 			${_test_name}
 			${NAME}
 			JUNIT
 			"--run_test=${_test_name}"
 			"--logger=${HRF_LOGGER}${JUNIT_LOGGER}"
 		)
 		set_property(
 			TARGET ${SUITE_TARGET}
 			APPEND PROPERTY UNIT_TESTS ${_test_name}
 		)
 	endforeach()
 
 	find_package(Boost 1.59 REQUIRED unit_test_framework)
 	target_link_libraries(${NAME} Boost::unit_test_framework)
 
 	# We need to detect if the BOOST_TEST_DYN_LINK flag is required
 	include(CheckCXXSourceCompiles)
 	set(CMAKE_REQUIRED_LIBRARIES Boost::unit_test_framework)
 
 	check_cxx_source_compiles("
 		#define BOOST_TEST_DYN_LINK
 		#define BOOST_TEST_MAIN
 		#include <boost/test/unit_test.hpp>
 	" BOOST_REQUIRES_TEST_DYN_LINK)
 
 	if(BOOST_REQUIRES_TEST_DYN_LINK)
 		target_compile_definitions(${NAME} PRIVATE BOOST_TEST_DYN_LINK)
 	endif()
 endfunction(add_boost_unit_tests_to_suite)
diff --git a/test/CMakeLists.txt b/test/CMakeLists.txt
index ec414f580..5db925899 100644
--- a/test/CMakeLists.txt
+++ b/test/CMakeLists.txt
@@ -1,134 +1,137 @@
 ###
 # Create config.ini file for tests
 ###
 if("fuzzer" IN_LIST ENABLE_SANITIZERS)
 	set(ENABLE_FUZZ ON)
 else()
 	set(ENABLE_FUZZ OFF)
 endif()
 
 # Create build ini file
 configure_file(config.ini.cmake.in config.ini)
 
 ###
 # Setup symlinks for testing
 ###
 include(SanitizeHelper)
 function(make_link file)
 	set(src "${CMAKE_CURRENT_SOURCE_DIR}/${file}")
 	set(dest "${CMAKE_CURRENT_BINARY_DIR}/${file}")
 
 	# Create the target directory and parents if needed.
 	get_filename_component(dest_dir "${dest}" DIRECTORY)
 	file(MAKE_DIRECTORY "${dest_dir}")
 
 	add_custom_command(
 		OUTPUT "${dest}"
 		COMMAND ${CMAKE_COMMAND} -E create_symlink "${src}" "${dest}"
 		COMMENT "link ${file}"
 		MAIN_DEPENDENCY "${src}"
 	)
 	# Add a phony target to make sure the files are linked by default.
 	sanitize_target_name("link-" "${file}" NAME)
 	add_custom_target(${NAME} ALL DEPENDS "${dest}")
 endfunction()
 
 make_link(functional/test_runner.py)
 make_link(util/bitcoin-util-test.py)
 make_link(util/rpcauth-test.py)
 make_link(fuzz/test_runner.py)
 
 include(Coverage)
 include(TestSuite)
 
 set(_TEST_TARGET_DEPENDS "")
 if(BUILD_BITCOIN_CLI)
 	list(APPEND _TEST_TARGET_DEPENDS bitcoin-cli)
 endif()
 if(BUILD_BITCOIN_WALLET)
 	list(APPEND _TEST_TARGET_DEPENDS bitcoin-wallet)
 endif()
 
-macro(add_functional_test_check TARGET COMMENT)
+function(add_functional_test_check TARGET DESCRIPTION)
+	if(ENABLE_JUNIT_REPORT)
+		string(REGEX REPLACE " " "_" JUNIT_FILE "${DESCRIPTION}.xml")
+		set(JUNIT_OUTPUT "--junitoutput=${JUNIT_REPORT_DIRECTORY}/${JUNIT_FILE}")
+	endif()
+
 	add_test_custom_target(${TARGET}
 		TEST_COMMAND
 			"${Python_EXECUTABLE}"
 			./functional/test_runner.py
+			"--testsuitename=Bitcoin ABC ${DESCRIPTION}"
+			${JUNIT_OUTPUT}
 			${ARGN}
 		CUSTOM_TARGET_ARGS
-			COMMENT "${COMMENT}"
+			COMMENT "Running ${DESCRIPTION}"
 			DEPENDS
 				bitcoind
 				${_TEST_TARGET_DEPENDS}
 				${CMAKE_CURRENT_BINARY_DIR}/functional/test_runner.py
 			USES_TERMINAL
 			VERBATIM
 	)
 
 	add_custom_target_coverage(${TARGET})
-endmacro()
+endfunction()
 
 add_functional_test_check(check-functional
-	"Run the functional tests"
+	"functional tests"
 )
 add_dependencies(check-all check-functional)
 
 add_functional_test_check(check-functional-extended
-	"Run the extended functional tests"
+	"extended functional tests"
 	--extended
 )
 add_dependencies(check-extended check-functional-extended)
 
-set(TEST_SUITE_NAME_UPGRADE_ACTIVATED "Bitcoin ABC functional tests with the next upgrade activated")
-
 add_functional_test_check(check-functional-upgrade-activated
-	"Run the functional tests with the upgrade activated"
+	"functional tests with the next upgrade activated"
 	--with-axionactivation
-	-n "${TEST_SUITE_NAME_UPGRADE_ACTIVATED}"
 )
 add_dependencies(check-upgrade-activated check-functional-upgrade-activated)
 
 add_functional_test_check(check-functional-upgrade-activated-extended
-	"Run the extended functional tests with the upgrade activated"
+	"extended functional tests with the next upgrade activated"
 	--extended
 	--with-axionactivation
-	-n "${TEST_SUITE_NAME_UPGRADE_ACTIVATED}"
 )
 add_dependencies(check-upgrade-activated-extended check-functional-upgrade-activated-extended)
 
 if(BUILD_BITCOIN_TX)
 	add_test_custom_target(check-bitcoin-util
 		TEST_COMMAND
 			"${Python_EXECUTABLE}"
 			./util/bitcoin-util-test.py
 		CUSTOM_TARGET_ARGS
 			COMMENT "Test Bitcoin utilities..."
 			DEPENDS
 				bitcoin-tx
 				${CMAKE_CURRENT_BINARY_DIR}/util/bitcoin-util-test.py
 	)
 
 	add_dependencies(check check-bitcoin-util)
 endif()
 
 add_custom_target(check-rpcauth
 	COMMENT "Test Bitcoin RPC authentication..."
 	COMMAND
 		"${Python_EXECUTABLE}"
 		./util/rpcauth-test.py
 	DEPENDS
 		${CMAKE_CURRENT_BINARY_DIR}/util/rpcauth-test.py
 )
 
 add_dependencies(check check-rpcauth)
 
 include(PackageHelper)
 exclude_from_source_package(
 	# Subdirectories
 	"cache/"
 	"lint/"
 	"sanitizer_suppressions/"
 )
 
 
 set_property(DIRECTORY "${CMAKE_SOURCE_DIR}" APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/cache")