diff --git a/cmake/modules/AddCompilerFlags.cmake b/cmake/modules/AddCompilerFlags.cmake
index 632f8c080..11e10ea2b 100644
--- a/cmake/modules/AddCompilerFlags.cmake
+++ b/cmake/modules/AddCompilerFlags.cmake
@@ -1,142 +1,142 @@
 # Allow to easily add flags for C and C++
 include(CheckCXXCompilerFlag)
 include(CheckCCompilerFlag)
 include(SanitizeHelper)
 
 function(check_compiler_flag RESULT LANGUAGE FLAG)
 	sanitize_c_cxx_definition("have_${LANGUAGE}_" ${FLAG} TEST_NAME)
 
 	if("${LANGUAGE}" STREQUAL "C")
 		CHECK_C_COMPILER_FLAG(${FLAG} ${TEST_NAME})
 	elseif("${LANGUAGE}" STREQUAL "CXX")
 		CHECK_CXX_COMPILER_FLAG(${FLAG} ${TEST_NAME})
 	else()
 		message(FATAL_ERROR "check_compiler_flag LANGUAGE should be C or CXX")
 	endif()
 	set(${RESULT} ${${TEST_NAME}} PARENT_SCOPE)
 endfunction()
 
-function(add_c_compiler_flag)
+function(add_c_compiler_flags)
 	foreach(f ${ARGN})
 		check_compiler_flag(FLAG_IS_SUPPORTED C ${f})
 		if(${FLAG_IS_SUPPORTED})
 			string(APPEND CMAKE_C_FLAGS " ${f}")
 		endif()
 	endforeach()
 	set(CMAKE_C_FLAGS ${CMAKE_C_FLAGS} PARENT_SCOPE)
 endfunction()
 
-function(add_cxx_compiler_flag)
+function(add_cxx_compiler_flags)
 	foreach(f ${ARGN})
 		check_compiler_flag(FLAG_IS_SUPPORTED CXX ${f})
 		if(${FLAG_IS_SUPPORTED})
 			string(APPEND CMAKE_CXX_FLAGS " ${f}")
 		endif()
 	endforeach()
 	set(CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} PARENT_SCOPE)
 endfunction()
 
-macro(add_compiler_flag)
-	add_c_compiler_flag(${ARGN})
-	add_cxx_compiler_flag(${ARGN})
+macro(add_compiler_flags)
+	add_c_compiler_flags(${ARGN})
+	add_cxx_compiler_flags(${ARGN})
 endmacro()
 
 macro(remove_c_compiler_flags)
 	if(NOT "${CMAKE_BUILD_TYPE}" STREQUAL "")
 		string(TOUPPER ${CMAKE_BUILD_TYPE} BUILD_TYPE)
 		set(BUILD_TYPE_C_FLAGS "CMAKE_C_FLAGS_${BUILD_TYPE}")
 	endif()
 	
 	foreach(f ${ARGN})
 		string(REGEX REPLACE "${f}( |$)" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 		if(NOT "${CMAKE_BUILD_TYPE}" STREQUAL "")
 			string(REGEX REPLACE "${f}( |$)" "" ${BUILD_TYPE_C_FLAGS} "${${BUILD_TYPE_C_FLAGS}}")
 		endif()
 	endforeach()
 endmacro()
 
 macro(remove_cxx_compiler_flags)
 	if(NOT "${CMAKE_BUILD_TYPE}" STREQUAL "")
 		string(TOUPPER ${CMAKE_BUILD_TYPE} BUILD_TYPE)
 		set(BUILD_TYPE_CXX_FLAGS "CMAKE_CXX_FLAGS_${BUILD_TYPE}")
 	endif()
 	
 	foreach(f ${ARGN})
 		string(REGEX REPLACE "${f}( |$)" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 		if(NOT "${CMAKE_BUILD_TYPE}" STREQUAL "")
 			string(REGEX REPLACE "${f}( |$)" "" ${BUILD_TYPE_CXX_FLAGS} "${${BUILD_TYPE_CXX_FLAGS}}")
 		endif()
 	endforeach()
 endmacro()
 
 macro(remove_compiler_flags)
 	remove_c_compiler_flags(${ARGN})
 	remove_cxx_compiler_flags(${ARGN})
 endmacro()
 
 function(add_cxx_compiler_flag_with_fallback TARGET_VAR FLAG FALLBACK)
 	# Remove the fallback flag if it exists, so that the main flag will override
 	# it if it was previously added.
 	remove_cxx_compiler_flags(${FALLBACK})
 	
 	set(FLAG_CANDIDATE ${FLAG})
 	check_compiler_flag(FLAG_IS_SUPPORTED CXX ${FLAG_CANDIDATE})
 	if(NOT ${FLAG_IS_SUPPORTED})
 		set(FLAG_CANDIDATE ${FALLBACK})
 		check_compiler_flag(FLAG_IS_SUPPORTED CXX ${FLAG_CANDIDATE})
 	endif()
 	
 	if(${FLAG_IS_SUPPORTED})
 		string(APPEND ${TARGET_VAR} " ${FLAG_CANDIDATE}")
 		set(${TARGET_VAR} ${${TARGET_VAR}} PARENT_SCOPE)
 	endif()
 endfunction()
 
 # Note that CMake does not provide any facility to check that a linker flag is
 # supported by the compiler.
 # However since CMake 3.2 introduced the CMP0056 policy, the
 # CMAKE_EXE_LINKER_FLAGS variable is used by the try_compile function, so there
 # is a workaround that allow for testing the linker flags.
-function(add_linker_flag)
+function(add_linker_flags)
 	foreach(f ${ARGN})
 		sanitize_c_cxx_definition("have_linker_" ${f} FLAG_IS_SUPPORTED)
 
 		# Some linkers (e.g.: Clang) will issue a -Wunused-command-line-argument
 		# warning when an unknown linker flag is set.
 		# Using -Werror will promote these warnings to errors so
 		# CHECK_CXX_COMPILER_FLAG() will return false, preventing the flag from
 		# being set.
 		check_compiler_flag(WUNUSED_CLI_ARGUMENT_IS_SUPPORTED
 			CXX
 			"-Wunused-command-line-argument"
 		)
 		if(${WUNUSED_CLI_ARGUMENT_IS_SUPPORTED})
 			string(APPEND
 				CMAKE_REQUIRED_FLAGS
 				" -Werror=unused-command-line-argument"
 			)
 		endif()
 
 		# Save the current linker flags
 		set(SAVE_CMAKE_EXE_LINKERFLAGS ${CMAKE_EXE_LINKER_FLAGS})
 		string(APPEND CMAKE_EXE_LINKER_FLAGS " ${f}")
 
 		# CHECK_CXX_COMPILER_FLAG calls CHECK_CXX_SOURCE_COMPILES which in turn
 		# calls try_compile, so it will check our flag
 		CHECK_CXX_COMPILER_FLAG("" ${FLAG_IS_SUPPORTED})
 
 		# Unset the -Werror=unused-command-line-argument flag if it is set.
 		string(REGEX REPLACE
 			" -Werror=unused-command-line-argument"
 			""
 			CMAKE_REQUIRED_FLAGS
 			"${CMAKE_REQUIRED_FLAGS}"
 		)
 
 		# If the flag is not supported restore CMAKE_EXE_LINKER_FLAGS
 		if(NOT ${FLAG_IS_SUPPORTED})
 			set(CMAKE_EXE_LINKER_FLAGS ${SAVE_CMAKE_EXE_LINKERFLAGS})
 		endif()
 	endforeach()
 	set(CMAKE_EXE_LINKER_FLAGS ${CMAKE_EXE_LINKER_FLAGS} PARENT_SCOPE)
 endfunction()
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
index 5c12fd4e9..32249a752 100644
--- a/src/CMakeLists.txt
+++ b/src/CMakeLists.txt
@@ -1,461 +1,461 @@
 # Copyright (c) 2017 The Bitcoin developers
 
 cmake_minimum_required(VERSION 3.5)
 project(BitcoinABC)
 
 set(CMAKE_CXX_STANDARD 14)
 
 # Default visibility is hidden on all targets.
 set(CMAKE_C_VISIBILITY_PRESET hidden)
 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
 
 option(BUILD_BITCOIN_WALLET "Activate the wallet functionality" ON)
 option(BUILD_BITCOIN_ZMQ "Activate the ZeroMQ functionalities" ON)
 option(BUILD_BITCOIN_SEEDER "Build bitcoin-seeder" ON)
 option(BUILD_BITCOIN_CLI "Build bitcoin-cli" ON)
 option(BUILD_BITCOIN_TX "Build bitcoin-tx" ON)
 option(BUILD_BITCOIN_QT "Build bitcoin-qt" ON)
 option(ENABLE_HARDENING "Harden the executables" ON)
 option(ENABLE_REDUCE_EXPORTS "Reduce the amount of exported symbols" OFF)
 option(ENABLE_STATIC_LIBSTDCXX "Statically link libstdc++" OFF)
 option(ENABLE_GLIBC_BACK_COMPAT "Enable Glibc compatibility features" OFF)
 option(ENABLE_QRCODE "Enable QR code display" ON)
 option(ENABLE_UPNP "Enable UPnP support" ON)
 option(START_WITH_UPNP "Make UPnP the default to map ports" OFF)
 
 # Allow usage of sanitizers by setting ECM_ENABLE_SANITIZERS
 if(ENABLE_SANITIZERS)
 	set(ECM_ENABLE_SANITIZERS ${ENABLE_SANITIZERS})
 	find_package(ECM NO_MODULE)
 	if(ECM_MODULE_PATH)
 		list(APPEND CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
 		include(ECMEnableSanitizers)
 	else()
 		message(FATAL_ERROR
 			"ECM is required to enable the sanitizers (https://api.kde.org/ecm/index.html)"
 		)
 	endif()
 endif()
 
 # Cmake uses the CMAKE_BUILD_TYPE variable to select the build configuration.
 # By default it supports more configurations that needed for Bitcoin ABC, and
 # all the releases types set NDEBUG which is unwanted as it disables the assert
 # completely.
 # Remove the -DNDEBUG flag from the CFLAGS/CXXFLAGS in all the configurations
 include(AddCompilerFlags)
 remove_compiler_flags(-DNDEBUG)
 
 # Overrides the flags for the Debug build type
 # This mimics the autotools behavior by setting the CFLAGS to '-g -O2`, which
 # are not well suited for debugging.
 # FIXME: update CFLAGS with better debug oriented optimization flags
 set(CMAKE_C_FLAGS_DEBUG "-g -O2")
 
 # Prefer -g3, defaults to -g if unavailable
 add_cxx_compiler_flag_with_fallback(CMAKE_CXX_FLAGS_DEBUG -g3 -g)
 
 # Prefer -Og, defaults to -O0 if unavailable
 add_cxx_compiler_flag_with_fallback(CMAKE_CXX_FLAGS_DEBUG -Og -O0)
 
 # Define the debugging symbols DEBUG and DEBUG_LOCKORDER when the Debug build
 # type is selected.
 string(APPEND CMAKE_CXX_FLAGS_DEBUG " -DDEBUG -DDEBUG_LOCKORDER")
 
 # Ensure that WINDRES_PREPROC is enabled when using windres.
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	# Ensure that WINDRES_PREPROC is enabled when using windres.
 	list(APPEND CMAKE_RC_FLAGS "-DWINDRES_PREPROC")
 
 	# Build all static so there is no dll file to distribute.
-	add_compiler_flag(-static)
+	add_compiler_flags(-static)
 endif()
 
 if(ENABLE_REDUCE_EXPORTS)
 	# Default visibility is set by CMAKE_<LANG>_VISIBILITY_PRESET, but this
 	# doesn't tell if the visibility set is effective.
 	# Check if the flag -fvisibility=hidden is supported, as using the hidden
 	# visibility is a requirement to reduce exports.
 	check_compiler_flag(HAS_CXX_FVISIBILITY CXX -fvisibility=hidden)
 	if(NOT HAS_CXX_FVISIBILITY)
 		message(FATAL_ERROR "Cannot set default symbol visibility. Use -DENABLE_REDUCE_EXPORTS=OFF.")
 	endif()
 
 	# Also hide symbols from static libraries
-	add_linker_flag(-Wl,--exclude-libs,ALL)
+	add_linker_flags(-Wl,--exclude-libs,ALL)
 endif()
 
 # Enable statically linking libstdc++
 if(ENABLE_STATIC_LIBSTDCXX)
-	add_linker_flag(-static-libstdc++)
+	add_linker_flags(-static-libstdc++)
 endif()
 
 # All windows code is PIC, forcing it on just adds useless compile warnings
 if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Windows")
-	add_compiler_flag(-fPIC)
+	add_compiler_flags(-fPIC)
 endif()
 
 if(ENABLE_HARDENING)
 	# Enable stack protection
-	add_cxx_compiler_flag(-fstack-protector-all -Wstack-protector)
+	add_cxx_compiler_flags(-fstack-protector-all -Wstack-protector)
 
 	# Enable some buffer overflow checking
-	add_compiler_flag(-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2)
+	add_compiler_flags(-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2)
 
 	# Enable ASLR (these flags are primarily targeting MinGw)
-	add_linker_flag(-Wl,--dynamicbase -Wl,--nxcompat -Wl,--high-entropy-va)
+	add_linker_flags(-Wl,--dynamicbase -Wl,--nxcompat -Wl,--high-entropy-va)
 
 	# Make the relocated sections read-only
-	add_linker_flag(-Wl,-z,relro -Wl,-z,now)
+	add_linker_flags(-Wl,-z,relro -Wl,-z,now)
 
 	# CMake provides the POSITION_INDEPENDENT_CODE property to set PIC/PIE.
 	# Unfortunately setting the -pie linker flag this way require CMake >= 3.14,
 	# which is not widely distributed at the time of writing.
 	# FIXME: use the POSITION_INDEPENDENT_CODE property instead
-	add_compiler_flag(-fPIE)
-	add_linker_flag(-pie)
+	add_compiler_flags(-fPIE)
+	add_linker_flags(-pie)
 
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		# MinGw provides its own libssp for stack smashing protection
 		link_libraries(ssp)
 	endif()
 endif()
 
 # Enable warning
-add_c_compiler_flag(-Wnested-externs -Wstrict-prototypes)
-add_compiler_flag(
+add_c_compiler_flags(-Wnested-externs -Wstrict-prototypes)
+add_compiler_flags(
 	-Wall
 	-Wextra
 	-Wformat
 	-Wvla
 	-Wformat-security
 	-Wcast-align
 	-Wunused-parameter
 	-Wmissing-braces
 	-Wthread-safety-analysis
 	-Wshadow
 	-Wrange-loop-analysis
 )
 
 option(EXTRA_WARNINGS "Enable extra warnings" OFF)
 if(EXTRA_WARNINGS)
-	add_cxx_compiler_flag(-Wsuggest-override)
+	add_cxx_compiler_flags(-Wsuggest-override)
 else()
-	add_compiler_flag(-Wno-unused-parameter)
-	add_compiler_flag(-Wno-implicit-fallthrough)
+	add_compiler_flags(-Wno-unused-parameter)
+	add_compiler_flags(-Wno-implicit-fallthrough)
 endif()
 
 # Create a target for OpenSSL
 include(BrewHelper)
 find_brew_prefix(OPENSSL_ROOT_DIR openssl)
 find_package(OpenSSL REQUIRED)
 
 # libtool style configure
 add_subdirectory(config)
 
 # libraries
 add_subdirectory(crypto)
 add_subdirectory(leveldb)
 add_subdirectory(secp256k1)
 add_subdirectory(univalue)
 
 # Because the Bitcoin ABc source code is disorganised, we
 # end up with a bunch of libraries without any apparent
 # cohesive structure. This is inherited from Bitcoin Core
 # and reflecting this.
 # TODO: Improve the structure once cmake is rocking.
 
 # Various completely unrelated features shared by all executables.
 add_library(util
 	chainparamsbase.cpp
 	clientversion.cpp
 	compat/glibc_sanity.cpp
 	compat/glibcxx_sanity.cpp
 	compat/strnlen.cpp
 	fs.cpp
 	logging.cpp
 	random.cpp
 	rcu.cpp
 	rpc/protocol.cpp
 	rpc/util.cpp
 	support/cleanse.cpp
 	support/lockedpool.cpp
 	sync.cpp
 	threadinterrupt.cpp
 	uint256.cpp
 	util.cpp
 	utilmoneystr.cpp
 	utilstrencodings.cpp
 	utiltime.cpp
 	util/bytevectorhash.cpp
 )
 
 target_compile_definitions(util PUBLIC HAVE_CONFIG_H)
 target_include_directories(util
 	PUBLIC
 		.
 		# To access the config.
 		${CMAKE_CURRENT_BINARY_DIR}
 )
 
 if(ENABLE_GLIBC_BACK_COMPAT)
 	# glibc absorbed clock_gettime in 2.17. librt (its previous location) is
 	# safe to link in anyway for back-compat.
 	find_library(RT_LIBRARY rt)
 	target_link_libraries(util ${RT_LIBRARY})
 
 	#__fdelt_chk's params and return type have changed from long unsigned int to
 	# long int. See which one is present here.
 	include(CheckPrototypeDefinition)
 
 	set(CMAKE_REQUIRED_DEFINITIONS -D_FORTIFY_SOURCE=2)
 	# Without some optimization the compiler won't detect the prototype conflict
 	# and always succeed to build.
 	set(CMAKE_REQUIRED_FLAGS -O2)
 
 	check_prototype_definition(
 		__fdelt_warn
 		"extern long unsigned int __fdelt_warn(long unsigned int a)"
 		"0"
 		"sys/select.h"
 		FDELT_PROTOTYPE_LONG_UNSIGNED_INT
 	)
 
 	if(FDELT_PROTOTYPE_LONG_UNSIGNED_INT)
 		set(FDELT_TYPE "long unsigned int")
 	else()
 		set(FDELT_TYPE "long int")
 	endif()
 
 	target_compile_definitions(util PRIVATE "-DFDELT_TYPE=${FDELT_TYPE}")
 
 	# Wrap some glibc functions with ours
-	add_linker_flag(-Wl,--wrap=__divmoddi4)
-	add_linker_flag(-Wl,--wrap=log2f)
+	add_linker_flags(-Wl,--wrap=__divmoddi4)
+	add_linker_flags(-Wl,--wrap=log2f)
 
 	target_sources(util PRIVATE compat/glibc_compat.cpp)
 endif()
 
 # Target specific configs
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	set(Boost_USE_STATIC_LIBS ON)
 	set(Boost_THREADAPI win32)
 
 	find_package(SHLWAPI REQUIRED)
 	target_link_libraries(util ${SHLWAPI_LIBRARY})
 	target_include_directories(util PUBLIC ${SHLWAPI_INCLUDE_DIR})
 
 	find_library(WS2_32_LIBRARY NAMES ws2_32)
 	target_link_libraries(util ${WS2_32_LIBRARY})
 
 	target_compile_definitions(util PUBLIC BOOST_THREAD_USE_LIB)
 endif()
 
 # Boost packages
 set(BOOST_PACKAGES_REQUIRED chrono filesystem thread)
 
 function(prepend var prefix)
 	set(listVar "")
 	foreach(f ${ARGN})
 		list(APPEND listVar "${prefix}${f}")
 	endforeach(f)
 	set(${var} "${listVar}" PARENT_SCOPE)
 endfunction(prepend)
 
 prepend(BOOST_LIBRARIES "Boost::" ${BOOST_PACKAGES_REQUIRED})
 
 find_package(Boost 1.58 REQUIRED ${BOOST_PACKAGES_REQUIRED})
 target_link_libraries(util univalue crypto ${BOOST_LIBRARIES})
 
 # Make sure boost uses std::atomic (it doesn't before 1.63)
 target_compile_definitions(util PUBLIC BOOST_SP_USE_STD_ATOMIC BOOST_AC_USE_STD_ATOMIC)
 
 # More completely unrelated features shared by all executables.
 # Because nothing says this is different from util than "common"
 add_library(common
 	amount.cpp
 	base58.cpp
 	cashaddr.cpp
 	cashaddrenc.cpp
 	chainparams.cpp
 	config.cpp
 	consensus/merkle.cpp
 	coins.cpp
 	compressor.cpp
 	feerate.cpp
 	globals.cpp
 	core_read.cpp
 	core_write.cpp
 	key.cpp
 	key_io.cpp
 	keystore.cpp
 	netaddress.cpp
 	netbase.cpp
 	primitives/block.cpp
 	protocol.cpp
 	scheduler.cpp
 	script/ismine.cpp
 	script/sign.cpp
 	script/standard.cpp
 	warnings.cpp
 )
 
 target_link_libraries(common util secp256k1)
 
 # libbitcoinconsensus
 add_library(bitcoinconsensus
 	arith_uint256.cpp
 	hash.cpp
 	primitives/transaction.cpp
 	pubkey.cpp
 	script/bitcoinconsensus.cpp
 	script/bitfield.cpp
 	script/interpreter.cpp
 	script/script.cpp
 	script/script_error.cpp
 	script/sigencoding.cpp
 	uint256.cpp
 	utilstrencodings.cpp
 )
 
 target_link_libraries(bitcoinconsensus common)
 
 # Bitcoin server facilities
 add_library(server
 	addrman.cpp
 	addrdb.cpp
 	avalanche.cpp
 	bloom.cpp
 	blockencodings.cpp
 	blockfilter.cpp
 	chain.cpp
 	checkpoints.cpp
 	config.cpp
 	consensus/activation.cpp
 	consensus/tx_verify.cpp
 	flatfile.cpp
 	globals.cpp
 	httprpc.cpp
 	httpserver.cpp
 	index/base.cpp
 	index/txindex.cpp
 	init.cpp
 	interfaces/handler.cpp
 	interfaces/node.cpp
 	dbwrapper.cpp
 	merkleblock.cpp
 	miner.cpp
 	net.cpp
 	net_processing.cpp
 	noui.cpp
 	policy/fees.cpp
 	policy/policy.cpp
 	pow.cpp
 	rest.cpp
 	rpc/abc.cpp
 	rpc/blockchain.cpp
 	rpc/command.cpp
 	rpc/jsonrpcrequest.cpp
 	rpc/mining.cpp
 	rpc/misc.cpp
 	rpc/net.cpp
 	rpc/rawtransaction.cpp
 	rpc/server.cpp
 	script/scriptcache.cpp
 	script/sigcache.cpp
 	timedata.cpp
 	torcontrol.cpp
 	txdb.cpp
 	txmempool.cpp
 	ui_interface.cpp
 	validation.cpp
 	validationinterface.cpp
 )
 
 # This require libevent
 find_package(Event REQUIRED)
 
 target_include_directories(server PRIVATE leveldb/helpers/memenv)
 
 target_link_libraries(server
 	Event
 	bitcoinconsensus
 	leveldb
 	memenv
 )
 
 if(ENABLE_UPNP)
 	target_include_directories(server PUBLIC ${MINIUPNPC_INCLUDE_DIR})
 	target_link_libraries(server ${MINIUPNPC_LIBRARY})
 
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		find_library(IPHLPAPI_LIBRARY NAMES iphlpapi)
 		if(NOT IPHLPAPI_LIBRARY)
 			message(FATAL_ERROR "Lib iphlpapi is missing")
 		endif()
 		target_link_libraries(server ${IPHLPAPI_LIBRARY})
 
 		target_compile_definitions(server
 			PUBLIC -DSTATICLIB
 			PUBLIC -DMINIUPNP_STATICLIB
 		)
 	endif()
 endif()
 
 # Test suite.
 add_subdirectory(test)
 
 # Benchmark suite.
 add_subdirectory(bench)
 
 # Wallet
 if(BUILD_BITCOIN_WALLET)
 	add_subdirectory(wallet)
 	target_link_libraries(server wallet)
 endif()
 
 # ZeroMQ
 if(BUILD_BITCOIN_ZMQ)
 	add_subdirectory(zmq)
 	target_link_libraries(server zmq)
 endif()
 
 # RPC client support
 add_library(rpcclient rpc/client.cpp)
 target_link_libraries(rpcclient univalue util)
 
 # bitcoin-seeder
 if(BUILD_BITCOIN_SEEDER)
 	add_subdirectory(seeder)
 endif()
 
 # bitcoin-cli
 if(BUILD_BITCOIN_CLI)
 	add_executable(bitcoin-cli bitcoin-cli.cpp)
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		target_sources(bitcoin-cli PRIVATE bitcoin-cli-res.rc)
 	endif()
 
 	target_link_libraries(bitcoin-cli common rpcclient Event)
 endif()
 
 # bitcoin-tx
 if(BUILD_BITCOIN_TX)
 	add_executable(bitcoin-tx bitcoin-tx.cpp)
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 		target_sources(bitcoin-tx PRIVATE bitcoin-tx-res.rc)
 	endif()
 
 	target_link_libraries(bitcoin-tx bitcoinconsensus)
 endif()
 
 # bitcoind
 add_executable(bitcoind bitcoind.cpp)
 target_link_libraries(bitcoind server)
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	target_sources(bitcoind PRIVATE bitcoind-res.rc)
 endif()
 
 # Bitcoin-qt
 if(BUILD_BITCOIN_QT)
 	add_subdirectory(qt)
 endif()
diff --git a/src/leveldb/CMakeLists.txt b/src/leveldb/CMakeLists.txt
index a2bfc9ca4..91dd1b18c 100644
--- a/src/leveldb/CMakeLists.txt
+++ b/src/leveldb/CMakeLists.txt
@@ -1,222 +1,222 @@
 # Copyright 2017 The LEVELDB Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file. See the AUTHORS file for names of contributors.
 
 cmake_minimum_required(VERSION 3.5)
 project(Leveldb VERSION 0.1.0 LANGUAGES C CXX)
 
 # This project can take advantage of C++11.
 set(CMAKE_CXX_STANDARD 11)
 
 # Remove some warnings for leveldb as they can get noisy.
-add_compiler_flag(-Wno-sign-compare -Wno-implicit-fallthrough)
-add_c_compiler_flag(-Wno-strict-prototypes)
+add_compiler_flags(-Wno-sign-compare -Wno-implicit-fallthrough)
+add_c_compiler_flags(-Wno-strict-prototypes)
 remove_compiler_flags(-Wstrict-prototypes)
 
 include(CheckIncludeFileCXX)
 check_include_file_cxx("atomic" LEVELDB_ATOMIC_PRESENT)
 
 include_directories(.)
 
 # Leveldb library
 add_library(leveldb
 	db/builder.cc
 	db/c.cc
 	db/dbformat.cc
 	db/db_impl.cc
 	db/db_iter.cc
 	db/dumpfile.cc
 	db/filename.cc
 	db/log_reader.cc
 	db/log_writer.cc
 	db/memtable.cc
 	db/repair.cc
 	db/table_cache.cc
 	db/version_edit.cc
 	db/version_set.cc
 	db/write_batch.cc
 	table/block_builder.cc
 	table/block.cc
 	table/filter_block.cc
 	table/format.cc
 	table/iterator.cc
 	table/merger.cc
 	table/table_builder.cc
 	table/table.cc
 	table/two_level_iterator.cc
 	util/arena.cc
 	util/bloom.cc
 	util/cache.cc
 	util/coding.cc
 	util/comparator.cc
 	util/crc32c.cc
 	util/env.cc
 	util/env_posix.cc
 	util/filter_policy.cc
 	util/hash.cc
 	util/histogram.cc
 	util/logging.cc
 	util/options.cc
 	util/status.cc
 )
 
 # The SSE4.2 optimized CRC32 implementation.
 add_library(leveldb-sse4.2 port/port_posix_sse.cc)
 target_link_libraries(leveldb leveldb-sse4.2)
 
 # The libmemenv library.
 add_library(memenv helpers/memenv/memenv.cc)
 
 # Select the proper port: posix or Windows.
 if(${CMAKE_SYSTEM_NAME} MATCHES "Windows")
 	set(LEVELDB_PLATFORM WINDOWS)
 	set(LEVELDB_OS WINDOWS)
 	target_sources(leveldb
 		PRIVATE
 			util/env_win.cc
 			port/port_win.cc
 	)
 	target_compile_definitions(leveldb
 		PRIVATE
 			WINVER=0x0500
 			__USE_MINGW_ANSI_STDIO=1
 	)
 
 	find_package(SHLWAPI REQUIRED)
 	target_link_libraries(leveldb ${SHLWAPI_LIBRARY})
 	target_include_directories(leveldb PUBLIC ${SHLWAPI_INCLUDE_DIR})
 else()
 	set(LEVELDB_PLATFORM POSIX)
 	target_sources(leveldb PRIVATE port/port_posix.cc)
 
 	set(THREADS_PREFER_PTHREAD_FLAG ON)
 	find_package(Threads REQUIRED)
 	target_link_libraries(leveldb Threads::Threads)
 
 	if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 		set(LEVELDB_OS LINUX)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 		set(LEVELDB_OS MACOSX)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "(Solaris|SunOS)")
 		set(LEVELDB_OS SOLARIS)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 		set(LEVELDB_OS FREEBSD)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "NetBSD")
 		set(LEVELDB_OS NETBSD)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD")
 		set(LEVELDB_OS OPENBSD)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "DragonFly")
 		set(LEVELDB_OS DRAGONFLYBSD)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "Android")
 		set(LEVELDB_OS ANDROID)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "HPUX")
 		# No idea what's the proper system name is here.
 		set(LEVELDB_OS HPUX)
 	elseif(${CMAKE_SYSTEM_NAME} MATCHES "iOS")
 		# No idea what's the proper system name is here.
 		set(LEVELDB_OS IOS)
 	else()
 		# Unknown plateform, assume linux.
 		set(LEVELDB_OS LINUX)
 	endif()
 endif()
 
 # Right now this is not used but the latest version of leveldb uses this
 # so we might as well be ready for it.
 if (HAVE_CRC32C)
   target_link_libraries(leveldb crc32c)
 endif (HAVE_CRC32C)
 if (HAVE_SNAPPY)
   target_link_libraries(leveldb snappy)
 endif (HAVE_SNAPPY)
 
 # Configure all leveldb libraries.
 function(configure_leveldb_lib LIB)
 	target_include_directories(${LIB} PUBLIC include)
 	target_compile_definitions(${LIB}
 		PUBLIC
 			OS_${LEVELDB_OS}
 			LEVELDB_PLATFORM_${LEVELDB_PLATFORM}
 	)
 	if(LEVELDB_ATOMIC_PRESENT)
 		target_compile_definitions(${LIB} PUBLIC LEVELDB_ATOMIC_PRESENT)
 	endif(LEVELDB_ATOMIC_PRESENT)
 endfunction()
 
 configure_leveldb_lib(leveldb)
 configure_leveldb_lib(leveldb-sse4.2)
 configure_leveldb_lib(memenv)
 
 # Check support for SSE4.2 and act accordingly.
 set(CMAKE_REQUIRED_FLAGS -msse4.2)
 check_c_source_compiles("
 	#include <stdint.h>
 	#if defined(_MSC_VER)
 	#include <intrin.h>
 	#elif defined(__GNUC__) && defined(__SSE4_2__)
 	#include <nmmintrin.h>
 	#endif
 	int main() {
 		uint64_t l = 0;
 		l = _mm_crc32_u8(l, 0);
 		l = _mm_crc32_u32(l, 0);
 		l = _mm_crc32_u64(l, 0);
 		return l;
 	}
 " ENABLE_HWCRC32)
 if(ENABLE_HWCRC32)
 	target_compile_definitions(leveldb-sse4.2 PRIVATE LEVELDB_PLATFORM_POSIX_SSE)
 	target_compile_options(leveldb-sse4.2 PRIVATE -msse4.2)
 endif()
 
 option(LEVELDB_BUILD_TESTS "Build LevelDB's unit tests" ON)
 if(LEVELDB_BUILD_TESTS)
 	include(TestSuite)
 	create_test_suite(leveldb)
 
 	add_library(leveldb_test_base
 		EXCLUDE_FROM_ALL
 		util/testharness.cc
 		util/testutil.cc
 	)
 
 	target_link_libraries(leveldb_test_base leveldb)
 
 	function(create_leveldb_test NAME FILES)
 		add_test_to_suite(leveldb ${NAME} EXCLUDE_FROM_ALL ${FILES})
 		target_link_libraries(${NAME} leveldb_test_base)
 	endfunction()
 
 	create_leveldb_test(autocompact_test db/autocompact_test.cc)
 	create_leveldb_test(corruption_test db/corruption_test.cc)
 	create_leveldb_test(db_test db/db_test.cc)
 	create_leveldb_test(dbformat_test db/dbformat_test.cc)
 	create_leveldb_test(fault_injection_test db/fault_injection_test.cc)
 	create_leveldb_test(filename_test db/filename_test.cc)
 	create_leveldb_test(log_test db/log_test.cc)
 	create_leveldb_test(recovery_test db/recovery_test.cc)
 	create_leveldb_test(skiplist_test db/skiplist_test.cc)
 	create_leveldb_test(version_edit_test db/version_edit_test.cc)
 	create_leveldb_test(version_set_test db/version_set_test.cc)
 	create_leveldb_test(write_batch_test db/write_batch_test.cc)
 	create_leveldb_test(issue178_test issues/issue178_test.cc)
 	create_leveldb_test(issue200_test issues/issue200_test.cc)
 	create_leveldb_test(filter_block_test table/filter_block_test.cc)
 	create_leveldb_test(table_test table/table_test.cc)
 	create_leveldb_test(arena_test util/arena_test.cc)
 	create_leveldb_test(bloom_test util/bloom_test.cc)
 	create_leveldb_test(cache_test util/cache_test.cc)
 	create_leveldb_test(coding_test util/coding_test.cc)
 	create_leveldb_test(crc32c_test util/crc32c_test.cc)
 	create_leveldb_test(env_test util/env_test.cc)
 	create_leveldb_test(hash_test util/hash_test.cc)
 
 	create_leveldb_test(memenv_test helpers/memenv/memenv_test.cc)
 	target_link_libraries(memenv_test memenv)
 
 	# These tests only work on posix
 	if(${LEVELDB_PLATFORM} MATCHES "POSIX")
 		create_leveldb_test(c_test db/c_test.c)
 		create_leveldb_test(env_posix_test util/env_posix_test.cc)
 	endif()
 endif(LEVELDB_BUILD_TESTS)
diff --git a/src/secp256k1/CMakeLists.txt b/src/secp256k1/CMakeLists.txt
index bf4245f2c..635b614b9 100644
--- a/src/secp256k1/CMakeLists.txt
+++ b/src/secp256k1/CMakeLists.txt
@@ -1,167 +1,167 @@
 # Copyright (c) 2017 The Bitcoin developers
 
 cmake_minimum_required(VERSION 3.5)
 project(secp256k1)
 
 # libsecp256k1 use a different set of flags.
-add_compiler_flag(
+add_compiler_flags(
 	-pedantic
 	-Wno-unused-function
 	-Wno-overlength-strings
 )
 
-add_c_compiler_flag(
+add_c_compiler_flags(
 	-std=c89
 	-Wno-long-long
 )
 
 # Default visibility is hidden on all targets.
 set(CMAKE_C_VISIBILITY_PRESET hidden)
 
 include_directories(
 	.
 	src
 	# For the config
 	${CMAKE_CURRENT_BINARY_DIR}/src
 )
 
 # The library
 add_library(secp256k1 src/secp256k1.c)
 target_include_directories(secp256k1 PUBLIC include)
 
 # We need to link in GMP
 find_package(GMP)
 if(GMP_FOUND)
 	target_include_directories(secp256k1 PUBLIC ${GMP_INCLUDE_DIR})
 	target_link_libraries(secp256k1 ${GMP_LIBRARY})
 	set(USE_NUM_GMP 1)
 	set(USE_FIELD_INV_NUM 1)
 	set(USE_SCALAR_INV_NUM 1)
 else()
 	set(USE_NUM_NONE 1)
 	set(USE_FIELD_INV_BUILTIN 1)
 	set(USE_SCALAR_INV_BUILTIN 1)
 endif()
 
 # We check if amd64 asm is supported.
 check_c_source_compiles("
 	#include <stdint.h>
 	int main() {
 		uint64_t a = 11, tmp;
 		__asm__ __volatile__(\"movq \$0x100000000,%1; mulq %%rsi\" : \"+a\"(a) : \"S\"(tmp) : \"cc\", \"%rdx\");
 		return 0;
 	}
 " USE_ASM_X86_64)
 
 # We make sure __int128 is defined
 include(CheckTypeSize)
 check_type_size(__int128 SIZEOF___INT128)
 if(SIZEOF___INT128 EQUAL 16)
 	set(HAVE___INT128 1)
 else()
 	# If we do not support __int128, we should be falling back
 	# on 32bits implementations for field and scalar.
 endif()
 
 # Detect if we are on a 32 or 64 bits plateform and chose
 # scalar and filed implementation accordingly
 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 	# 64 bits implementationr require either __int128 or asm support.
 	if (HAVE___INT128 OR USE_ASM_X86_64)
 		set(USE_SCALAR_4X64 1)
 		set(USE_FIELD_5X52 1)
 	else()
 		message(SEND_ERROR "Compiler does not support __int128 or insline assembly")
 	endif()
 else()
 	set(USE_SCALAR_8X32 1)
 	set(USE_FIELD_10X26 1)
 endif()
 
 # Executable internal to secp256k1 need to have the HAVE_CONFIG_H define set.
 # For convenience, we wrap this into a function.
 function(link_secp256k1_internal NAME)
 	target_link_libraries(${NAME} secp256k1)
 	target_compile_definitions(${NAME} PRIVATE HAVE_CONFIG_H SECP256K1_BUILD)
 endfunction(link_secp256k1_internal)
 
 # Phony target to build benchmarks
 add_custom_target(bench-secp256k1)
 
 function(add_secp256k1_bench NAME)
 	add_executable(${NAME} EXCLUDE_FROM_ALL ${ARGN})
 	link_secp256k1_internal(${NAME})
 	add_dependencies(bench-secp256k1 ${NAME})
 endfunction(add_secp256k1_bench)
 
 # ECDH module
 option(SECP256K1_ENABLE_MODULE_ECDH "Build libsecp256k1's ECDH module" OFF)
 if(SECP256K1_ENABLE_MODULE_ECDH)
 	set(ENABLE_MODULE_ECDH 1)
 	add_secp256k1_bench(bench_ecdh src/bench_ecdh.c)
 endif()
 
 # MultiSet module
 option(SECP256K1_ENABLE_MODULE_MULTISET "Build libsecp256k1's MULTISET module" ON)
 if(SECP256K1_ENABLE_MODULE_MULTISET)
     set(ENABLE_MODULE_MULTISET 1)
 	add_secp256k1_bench(bench_multiset src/bench_multiset.c)
 endif()
 
 # Recovery module
 option(SECP256K1_ENABLE_MODULE_RECOVERY "Build libsecp256k1's recovery module" ON)
 if(SECP256K1_ENABLE_MODULE_RECOVERY)
 	set(ENABLE_MODULE_RECOVERY 1)
 	add_secp256k1_bench(bench_recover src/bench_recover.c)
 endif()
 
 # Schnorr module
 option(SECP256K1_ENABLE_MODULE_SCHNORR "Build libsecp256k1's Schnorr module" ON)
 if(SECP256K1_ENABLE_MODULE_SCHNORR)
 	set(ENABLE_MODULE_SCHNORR 1)
 endif()
 
 # Static precomputation for eliptic curve mutliplication
 option(SECP256K1_ECMULT_STATIC_PRECOMPUTATION "Precompute libsecp256k1's eliptic curve mutliplication tables" ON)
 if(SECP256K1_ECMULT_STATIC_PRECOMPUTATION)
 	set(USE_ECMULT_STATIC_PRECOMPUTATION 1)
 
 	include(NativeExecutable)
 	add_native_executable(gen_context src/gen_context.c)
 
 	add_custom_command(
 		OUTPUT ecmult_static_context.h
 		COMMAND gen_context
 	)
 
 	target_sources(secp256k1 PRIVATE ecmult_static_context.h)
 endif()
 
 # Generate the config
 configure_file(src/libsecp256k1-config.h.cmake.in src/libsecp256k1-config.h ESCAPE_QUOTES)
 target_compile_definitions(secp256k1 PRIVATE HAVE_CONFIG_H SECP256K1_BUILD)
 
 # Tests
 option(SECP256K1_BUILD_TEST "Build secp256k1's unit tests" ON)
 if(SECP256K1_BUILD_TEST)
 	include(TestSuite)
 	create_test_suite(secp256k1)
 
 	function(create_secp256k1_test NAME FILES)
 		add_test_to_suite(secp256k1 ${NAME} EXCLUDE_FROM_ALL ${FILES})
 		link_secp256k1_internal(${NAME})
 	endfunction()
 
 	create_secp256k1_test(tests src/tests.c)
 	target_compile_definitions(tests PRIVATE VERIFY)
 
 	create_secp256k1_test(exhaustive_tests src/tests_exhaustive.c)
 	# This should not be enabled at the same time as coverage is.
 	# TODO: support coverage.
 	target_compile_definitions(exhaustive_tests PRIVATE VERIFY)
 endif(SECP256K1_BUILD_TEST)
 
 # Benchmarks
 add_secp256k1_bench(bench_verify src/bench_verify.c)
 add_secp256k1_bench(bench_sign src/bench_sign.c)
 add_secp256k1_bench(bench_internal src/bench_internal.c)